testsuite/expect/test20.2

#!/usr/bin/expect
############################################################################
# Purpose: Test of SLURM functionality
#          qstat command tests
#
# Output:  "TEST: #.#" followed by "SUCCESS" if test was successful, OR
#          "FAILURE: ..." otherwise with an explanation of the failure, OR
#          anything else indicates a failure mode that must be investigated.
############################################################################
# Copyright (C) 2007 The Regents of the University of California.
# Produced at Lawrence Livermore National Laboratory (cf, DISCLAIMER).
# Written by Morris Jette <jette1@llnl.gov>
# UCRL-CODE-226842.
# 
# This file is part of SLURM, a resource management program.
# For details, see <http://www.llnl.gov/linux/slurm/>.
#  
# SLURM is free software; you can redistribute it and/or modify it under
# the terms of the GNU General Public License as published by the Free
# Software Foundation; either version 2 of the License, or (at your option)
# any later version.
# 
# SLURM is distributed in the hope that it will be useful, but WITHOUT ANY
# WARRANTY; without even the implied warranty of MERCHANTABILITY or FITNESS
# FOR A PARTICULAR PURPOSE.  See the GNU General Public License for more
# details.
# 
# You should have received a copy of the GNU General Public License along
# with SLURM; if not, write to the Free Software Foundation, Inc.,
# 59 Temple Place, Suite 330, Boston, MA  02111-1307  USA.
############################################################################
source ./globals

set test_id     "20.2"
set exit_code   0
set file_in	"test$test_id.input"
set file_out	"test$test_id.output"
set job_name	"test$test_id"

print_header $test_id

if {[file executable $qsub] == 0} {
	send_user "\nWARNING: $qsub does not exists\n"
	exit 0
}
if {[file executable $qstat] == 0} {
	send_user "\nWARNING: $qstat does not exists\n"
	exit 0
}
if {[file executable $qdel] == 0} {
	send_user "\nWARNING: $qdel does not exists\n"
	exit 0
}

set job_id 0
make_bash_script $file_in "sleep 60"
spawn $qsub -o $file_out -N $job_name $file_in
expect {
	-re "Submitted batch job ($number)" {
		set job_id $expect_out(1,string)
		exp_continue
	}
	timeout {
		send_user "\nFAILURE: qsub not responding\n"
		set exit_code 1
	}
	eof {
		wait
	}
}
if {$job_id == 0} {
	send_user "\nFAILURE: qsub failed to submit job\n"
	exit 1
}

set matches 0
spawn $qstat $job_id
expect {
	-re "$job_name" {
		incr matches
		exp_continue
	}
	timeout {
		send_user "\nFAILURE: qstat not responding\n"
		set exit_code 1
	}
	eof {
		wait
	}
}
if {$matches != 1} {
	send_user "\nFAILURE: qstat failed to report job\n"
	set exit_code 1
}
catch {exec $qdel $job_id}

if {$exit_code == 0} {
	exec $bin_rm -f $file_in $file_out
	send_user "\nSUCCESS\n"
}
exit $exit_code