/****************************************************************************
**
** Copyright (C) 2017 Klaralvdalens Datakonsult AB (KDAB).
** Contact: https://www.qt.io/licensing/
**
** This file is part of the Qt3D module of the Qt Toolkit.
**
** $QT_BEGIN_LICENSE:BSD$
** Commercial License Usage
** Licensees holding valid commercial Qt licenses may use this file in
** accordance with the commercial license agreement provided with the
** Software or, alternatively, in accordance with the terms contained in
** a written agreement between you and The Qt Company. For licensing terms
** and conditions see https://www.qt.io/terms-conditions. For further
** information use the contact form at https://www.qt.io/contact-us.
**
** BSD License Usage
** Alternatively, you may use this file under the terms of the BSD license
** as follows:
**
** "Redistribution and use in source and binary forms, with or without
** modification, are permitted provided that the following conditions are
** met:
**   * Redistributions of source code must retain the above copyright
**     notice, this list of conditions and the following disclaimer.
**   * Redistributions in binary form must reproduce the above copyright
**     notice, this list of conditions and the following disclaimer in
**     the documentation and/or other materials provided with the
**     distribution.
**   * Neither the name of The Qt Company Ltd nor the names of its
**     contributors may be used to endorse or promote products derived
**     from this software without specific prior written permission.
**
**
** THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS
** "AS IS" AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT
** LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR
** A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE COPYRIGHT
** OWNER OR CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL,
** SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT
** LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE,
** DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY
** THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT
** (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE
** OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE."
**
** $QT_END_LICENSE$
**
****************************************************************************/

import QtQuick 2.2 as QQ2
import Qt3D.Core 2.0
import Qt3D.Render 2.10
import Qt3D.Input 2.0
import Qt3D.Extras 2.0

Entity {
    id: sceneRoot

    Camera {
        id: camera
        projectionType: CameraLens.PerspectiveProjection
        fieldOfView: 45
        aspectRatio: 16/9
        nearPlane : 0.1
        farPlane : 1000.0
        position: Qt.vector3d( 0.0, 0.0, -40.0 )
        upVector: Qt.vector3d( 0.0, 1.0, 0.0 )
        viewCenter: Qt.vector3d( 0.0, 0.0, 0.0 )
    }

    RenderTarget {
        id: intermediateRenderTarget
        attachments : [
            RenderTargetOutput {
                objectName : "color"
                attachmentPoint : RenderTargetOutput.Color0
                texture : Texture2D {
                    id : colorAttachment0
                    width : 1024
                    height : 768
                    format : Texture.R32F
                    generateMipMaps : false
                    magnificationFilter : Texture.Linear
                    minificationFilter : Texture.Linear
                    wrapMode {
                        x: WrapMode.ClampToEdge
                        y: WrapMode.ClampToEdge
                    }
                }
            },
            RenderTargetOutput {
                objectName : "color"
                attachmentPoint : RenderTargetOutput.Color1
                texture : Texture2D {
                    id : colorAttachment1
                    width : 1024
                    height : 1024
                    format : Texture.R32F
                    generateMipMaps : false
                    magnificationFilter : Texture.Linear
                    minificationFilter : Texture.Linear
                    wrapMode {
                        x: WrapMode.ClampToEdge
                        y: WrapMode.ClampToEdge
                    }
                }
            }
        ]
    }

    components: [
        RenderSettings {
            activeFrameGraph: RenderSurfaceSelector {
                Viewport {
                    RenderTargetSelector {
                        target: intermediateRenderTarget
                        NoDraw  {}
                    }

                    RenderTargetSelector {
                        target: RenderTarget {
                            id: renderTarget
                            attachments : [
                                RenderTargetOutput {
                                    objectName : "color"
                                    attachmentPoint : RenderTargetOutput.Color0
                                    texture : Texture2D {
                                        id : colorAttachment
                                        width : 1024
                                        height : 768
                                        format : Texture.RGBA32F
                                        generateMipMaps : false
                                        magnificationFilter : Texture.Linear
                                        minificationFilter : Texture.Linear
                                        wrapMode {
                                            x: WrapMode.ClampToEdge
                                            y: WrapMode.ClampToEdge
                                        }
                                    }
                                },
                                RenderTargetOutput {
                                    objectName : "depth"
                                    attachmentPoint : RenderTargetOutput.Depth
                                    texture : Texture2D {
                                        id : depthAttachment
                                        width : 1024
                                        height : 1024
                                        format : Texture.D32F
                                        generateMipMaps : false
                                        magnificationFilter : Texture.Linear
                                        minificationFilter : Texture.Linear
                                        wrapMode {
                                            x: WrapMode.ClampToEdge
                                            y: WrapMode.ClampToEdge
                                        }
                                    }
                                }
                            ]
                        }
                        ClearBuffers {
                            clearColor: "white"
                            buffers: ClearBuffers.ColorDepthBuffer
                            CameraSelector {
                                camera: camera
                            }
                        }
                    }

                    NoDraw{

                        BlitFramebuffer {
                            source: renderTarget
                            destination: intermediateRenderTarget
                            sourceRect: Qt.rect(0,0,1024,768)
                            destinationRect: Qt.rect(0,0,1024,1024)
                            sourceAttachmentPoint: RenderTargetOutput.Color0
                            destinationAttachmentPoint: RenderTargetOutput.Color0
                            interpolationMethod: BlitFramebuffer.Linear
                        }

                        BlitFramebuffer {
                            source: intermediateRenderTarget
                            sourceRect: Qt.rect(0,0,1024,1024)
                            destinationRect: Qt.rect(0,0,512,384)
                            sourceAttachmentPoint: RenderTargetOutput.Color0
                            interpolationMethod: BlitFramebuffer.Linear
                        }

                        BlitFramebuffer {
                            source: renderTarget
                            sourceRect: Qt.rect(0,0,1024,768)
                            destinationRect: Qt.rect(0,384,512,384)
                            sourceAttachmentPoint: RenderTargetOutput.Color0
                            interpolationMethod: BlitFramebuffer.Linear
                        }

                        BlitFramebuffer {
                            source: renderTarget
                            sourceRect: Qt.rect(128,200,256,256)
                            destinationRect: Qt.rect(512,384,512,384)
                            sourceAttachmentPoint: RenderTargetOutput.Color0
                            interpolationMethod: BlitFramebuffer.Linear
                        }

                        BlitFramebuffer {
                            source: renderTarget
                            sourceRect: Qt.rect(128,200,256,256)
                            destinationRect: Qt.rect(512,0,512,384)
                            sourceAttachmentPoint: RenderTargetOutput.Color0
                            interpolationMethod: BlitFramebuffer.Nearest
                        }
                    }
                }
            }
        }
    ]

    PhongMaterial {
        id: material
    }

    TorusMesh {
        id: torusMesh
        radius: 5
        minorRadius: 1
        rings: 100
        slices: 20
    }

    Transform {
        id: torusTransform
        scale3D: Qt.vector3d(1.5, 1, 0.5)
        rotation: fromAxisAndAngle(Qt.vector3d(1, 0, 0), 45)
    }

    Entity {
        id: torusEntity
        components: [ torusMesh, material, torusTransform ]
    }

    SphereMesh {
        id: sphereMesh
        radius: 3
    }

    Transform {
        id: sphereTransform
        property real userAngle: 0.0
        matrix: {
            var m = Qt.matrix4x4();
            m.rotate(userAngle, Qt.vector3d(0, 1, 0));
            m.translate(Qt.vector3d(20, 0, 0));
            return m;
        }
    }

    QQ2.NumberAnimation {
        target: sphereTransform
        property: "userAngle"
        duration: 10000
        from: 0
        to: 360

        loops: QQ2.Animation.Infinite
        running: true
    }

    Entity {
        id: sphereEntity
        components: [ sphereMesh, material, sphereTransform ]
    }
}