testsuite/expect/test2.7

#!/usr/bin/expect
############################################################################
# Purpose: Test of SLURM functionality
#          Validate scontrol pidinfo command.
#
# Output:  "TEST: #.#" followed by "SUCCESS" if test was successful, OR
#          "FAILURE: ..." otherwise with an explanation of the failure, OR
#          anything else indicates a failure mode that must be investigated.
############################################################################
# Copyright (C) 2002-2006 The Regents of the University of California.
# Produced at Lawrence Livermore National Laboratory (cf, DISCLAIMER).
# Written by Morris Jette <jette1@llnl.gov>
# UCRL-CODE-226842.
# 
# This file is part of SLURM, a resource management program.
# For details, see <http://www.llnl.gov/linux/slurm/>.
#  
# SLURM is free software; you can redistribute it and/or modify it under
# the terms of the GNU General Public License as published by the Free
# Software Foundation; either version 2 of the License, or (at your option)
# any later version.
# 
# SLURM is distributed in the hope that it will be useful, but WITHOUT ANY
# WARRANTY; without even the implied warranty of MERCHANTABILITY or FITNESS
# FOR A PARTICULAR PURPOSE.  See the GNU General Public License for more
# details.
# 
# You should have received a copy of the GNU General Public License along
# with SLURM; if not, write to the Free Software Foundation, Inc.,
# 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301  USA.
############################################################################
source ./globals

set test_id     "2.7"
set exit_code   0
set file_in     "test$test_id.input"
set file_out    "test$test_id.output"
set file_err    "test$test_id.error"
set job_id      0
set scontrol_id 0

print_header $test_id

# Delete left-over stdout/err files
file delete $file_out $file_err

#
# Build input script file
#
make_bash_script $file_in "$scontrol pidinfo \$\$"

#
# Spawn a srun batch job that uses stdout/err and confirm their contents
#
set srun_pid [spawn $srun --batch --output=$file_out --error=$file_err -t1 $file_in]
expect {
	-re "jobid ($number) submitted" {
		set job_id $expect_out(1,string)
		exp_continue
	}
	timeout {
		send_user "\nFAILURE: srun not responding\n"
		slow_kill $srun_pid
		set exit_code 1
	}
	eof {
		wait
	}
}

if {$job_id == 0} {
	send_user "\nFAILURE: batch submit failure\n"
	exec $bin_rm -f $file_in
	exit 1
}

#
# Wait for job to complete
#
if {[wait_for_job $job_id "DONE"] != 0} {
	send_user "\nFAILURE: waiting for job to complete\n"
	exec $bin_rm -f $file_in
	exit 1
}

#
# Verify job_id in output file
#
set rem_time 999
if {[wait_for_file $file_out] == 0} {
	spawn $bin_cat $file_out
	expect {
		-re "job id ($number)" {
			set scontrol_id $expect_out(1,string)
			exp_continue
		}
		-re "slurm_get_rem_time is ($number)" {
			set rem_time $expect_out(1,string)
			exp_continue
		}
		eof {
			wait
		}
	}
}
if {$rem_time > 60} {
	send_user "\nFAILURE: job remaining time is wrong $rem_time\n"
	set exit_code 1
}
if {$rem_time < 59} {
	send_user "\nFAILURE: job remaining time seems too small\n"
	set exit_code 1
}

#
# Check for errors in log
#
if {[wait_for_file $file_err] == 0} {
	spawn $bin_cat $file_err
	expect {
		-re "error" {
			send_user "\nFAILURE: some error encountered\n"
			set exit_code 1
		}
		eof {
			wait
		}
	}
}

if {$job_id != $scontrol_id} {
	send_user "\nFAILURE: scontrol pidinfo error\n"
	set exit_code 1
}
if {$exit_code == 0} {
	send_user "\nSUCCESS\n"
	exec $bin_rm -f $file_in $file_out $file_err
}
exit $exit_code