testsuite/expect/test9.4

#!/usr/bin/env expect
#############################################################################
# Purpose: Stress test of per-task output and input files
#
# Note:    To avoid one minute NFS propagation delays in the output files,
#          we create them ahead of time. Without explicitly file creation,
#          this test requires about one minute per cycle to execute.
#
# Note:    This script generates and then deletes files in the working
#          directory named test9.4.input, test9.4.[0-9]+.input, and
#          test9.4.[0-9]+.output
############################################################################
# Copyright (C) 2002-2007 The Regents of the University of California.
# Copyright (C) 2008-2010 Lawrence Livermore National Security.
# Produced at Lawrence Livermore National Laboratory (cf, DISCLAIMER).
# Written by Morris Jette <jette1@llnl.gov>
# CODE-OCEC-09-009. All rights reserved.
#
# This file is part of Slurm, a resource management program.
# For details, see <https://slurm.schedmd.com/>.
# Please also read the included file: DISCLAIMER.
#
# Slurm is free software; you can redistribute it and/or modify it under
# the terms of the GNU General Public License as published by the Free
# Software Foundation; either version 2 of the License, or (at your option)
# any later version.
#
# Slurm is distributed in the hope that it will be useful, but WITHOUT ANY
# WARRANTY; without even the implied warranty of MERCHANTABILITY or FITNESS
# FOR A PARTICULAR PURPOSE.  See the GNU General Public License for more
# details.
#
# You should have received a copy of the GNU General Public License along
# with Slurm; if not, write to the Free Software Foundation, Inc.,
# 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301  USA.
############################################################################
source ./globals

set file_in       "$test_dir/input"
set file_in_task  "$test_dir/$test_name.%t.input"
set file_out_task "$test_dir/$test_name.%t.output"
set job_name      $test_name
set cycle_count   2
set task_cnt      [get_total_cpus]
set node_cnt      [llength [get_nodes_by_state]]
set other_opts    "-O"

log_info "Using $task_cnt tasks"

#
# Create random text files for each task
#
for {set tsk 0} {$tsk < $task_cnt} {incr tsk} {
    set chars "abcdefghijklmnopqrstuvwxyzABCDEFGHIJKLMNOPQRSTUVWXYZ0123456789 "
    set out ""
    set len [expr {int(rand()*128)}]
    for {set i 0} {$i < $len} {incr i} {
        append out [string index $chars [expr {int(rand() * [string length $chars])}]]
    }
    run_command -fail "echo $out > $test_dir/$test_name.$tsk.input"
}

#
# Run cycle_count jobs to copy job input to job output and compare sizes
#
for {set inx 0} {$inx < $cycle_count} {incr inx} {
	# Remove files from previous cycle
	for {set tsk 0} {$tsk < $task_cnt} {incr tsk} {
		set file_out_glob "$test_dir/$test_name.$tsk.output"
		exec $bin_rm -f $file_out_glob
	}

	# Submit a job that copies -i to -o
	run_command -fail "$srun --job-name=$job_name -e - -i $file_in_task -o $file_out_task -n$task_cnt -N1-$node_cnt $other_opts -t1 $bin_cat -"

	# Test output file sizes
	for {set tsk 0} {$tsk < $task_cnt} {incr tsk} {
		set file_out_glob "$test_dir/$test_name.$tsk.output"
		set input [run_command_output -fail "cat $test_dir/$test_name.$tsk.input"]
		set output ""
		wait_for_file $file_out_glob
		wait_for {$output == $input} {
			set output [run_command_output -fail "cat $file_out_glob"]
		}
		subtest {$output == $input} "Output file ($output) should be the same than input file ($input)"
	}
}