| # Maintainer: Alexey Pavlov <alexpux@gmail.com> |
| |
| _realname=aribb24 |
| pkgbase=mingw-w64-${_realname} |
| pkgname="${MINGW_PACKAGE_PREFIX}-${_realname}" |
| pkgver=1.0.3 |
| pkgrel=3 |
| pkgdesc="A library for ARIB STD-B24, decoding JIS 8 bit characters and parsing MPEG-TS stream (mingw-w64)" |
| arch=('any') |
| mingw_arch=('mingw32' 'mingw64' 'ucrt64' 'clang64' 'clang32') |
| url="https://github.com/nkoriyama/aribb24" |
| license=("LGPL") |
| makedepends=("${MINGW_PACKAGE_PREFIX}-gcc") |
| depends=("${MINGW_PACKAGE_PREFIX}-libpng") |
| options=('strip' 'staticlibs') |
| source=("${_realname}-${pkgver}.tar.gz"::"https://github.com/nkoriyama/aribb24/archive/v${pkgver}.tar.gz" |
| 001-no-undefined.patch) |
| sha256sums=('f61560738926e57f9173510389634d8c06cabedfa857db4b28fb7704707ff128' |
| '2832363ed204051fbc34c34da0fbac993e7bc0213de3a34baf37b2622da87657') |
| |
| prepare() { |
| cd "${srcdir}"/${_realname}-${pkgver} |
| patch -p1 -i ${srcdir}/001-no-undefined.patch |
| ./bootstrap |
| } |
| |
| build() { |
| [[ -d "${srcdir}/build-${MINGW_CHOST}" ]] && rm -rf "${srcdir}/build-${MINGW_CHOST}" |
| mkdir -p "${srcdir}/build-${MINGW_CHOST}" && cd "${srcdir}/build-${MINGW_CHOST}" |
| ../${_realname}-${pkgver}/configure \ |
| --prefix=${MINGW_PREFIX} \ |
| --build=${MINGW_CHOST} \ |
| --host=${MINGW_CHOST} \ |
| --enable-static \ |
| --enable-shared |
| |
| make |
| } |
| |
| package() { |
| cd "${srcdir}/build-${MINGW_CHOST}" |
| make -j1 DESTDIR="${pkgdir}" install |
| } |
