| # Maintainer: Alexey Kasatkin <alexeikasatkin@gmail.com> |
| # Updated by: Diego Sogari <diego.sogari@gmail.com> |
| |
| _realname=geos |
| pkgbase=mingw-w64-${_realname} |
| pkgname="${MINGW_PACKAGE_PREFIX}-${_realname}" |
| pkgver=3.8.0 |
| pkgrel=1 |
| pkgdesc="C++ port of the Java Topology Suite (mingw-w64)" |
| arch=('any') |
| mingw_arch=('mingw32' 'mingw64' 'ucrt64' 'clang64' 'clang32') |
| url="https://trac.osgeo.org/geos/" |
| license=('LGPL') |
| makedepends=("${MINGW_PACKAGE_PREFIX}-gcc" "${MINGW_PACKAGE_PREFIX}-cmake") |
| options=('strip' '!emptydirs') |
| source=("https://download.osgeo.org/geos/geos-${pkgver}.tar.bz2") |
| sha256sums=('99114c3dc95df31757f44d2afde73e61b9f742f0b683fd1894cbbee05dda62d5') |
| |
| build() { |
| [[ -d "${srcdir}/build-${MINGW_CHOST}" ]] && rm -rf "${srcdir}/build-${MINGW_CHOST}" |
| mkdir -p "${srcdir}/build-${MINGW_CHOST}" && cd "${srcdir}/build-${MINGW_CHOST}" |
| |
| declare -a extra_config |
| if check_option "debug" "n"; then |
| extra_config+=("-DCMAKE_BUILD_TYPE=Release") |
| else |
| extra_config+=("-DCMAKE_BUILD_TYPE=Debug") |
| fi |
| |
| MSYS2_ARG_CONV_EXCL="-DCMAKE_INSTALL_PREFIX=" \ |
| ${MINGW_PREFIX}/bin/cmake \ |
| -G"MSYS Makefiles" \ |
| -DCMAKE_INSTALL_PREFIX=${MINGW_PREFIX} \ |
| "${extra_config[@]}" \ |
| -DDISABLE_GEOS_INLINE=ON \ |
| ../${_realname}-${pkgver} |
| |
| make |
| } |
| |
| package() { |
| cd "${srcdir}/build-${MINGW_CHOST}" |
| make DESTDIR=${pkgdir} install |
| } |
| |
| check() { |
| cd "${srcdir}/build-${MINGW_CHOST}" |
| ctest || true |
| } |
