| # Maintainer: Ignacio Casal Quinteiro <icq@gnome.org> |
| |
| _realname=libepoxy |
| pkgbase=mingw-w64-${_realname} |
| pkgname="${MINGW_PACKAGE_PREFIX}-${_realname}" |
| pkgver=1.5.5 |
| pkgrel=1 |
| pkgdesc="A library for handling OpenGL function pointer management for you (mingw-w64)" |
| arch=('any') |
| mingw_arch=('mingw32' 'mingw64' 'ucrt64' 'clang64' 'clang32') |
| url="https://github.com/anholt/libepoxy" |
| license=("MIT") |
| depends=("${MINGW_PACKAGE_PREFIX}-gcc-libs") |
| makedepends=("${MINGW_PACKAGE_PREFIX}-gcc" |
| "${MINGW_PACKAGE_PREFIX}-pkg-config" |
| "${MINGW_PACKAGE_PREFIX}-python" |
| "${MINGW_PACKAGE_PREFIX}-meson") |
| options=('strip' 'staticlibs') |
| source=(https://github.com/anholt/libepoxy/releases/download/${pkgver}/${_realname}-${pkgver}.tar.xz) |
| sha256sums=('261663db21bcc1cc232b07ea683252ee6992982276536924271535875f5b0556') |
| |
| build() { |
| [[ -d "${srcdir}/build-${MINGW_CHOST}" ]] && rm -rf "${srcdir}/build-${MINGW_CHOST}" |
| mkdir -p "${srcdir}/build-${MINGW_CHOST}" && cd "${srcdir}/build-${MINGW_CHOST}" |
| |
| MSYS2_ARG_CONV_EXCL="--prefix=" \ |
| meson \ |
| --prefix="${MINGW_PREFIX}" \ |
| --buildtype plain \ |
| -Ddefault_library=both \ |
| ../${_realname}-${pkgver} |
| |
| ninja |
| } |
| |
| package() { |
| cd "${srcdir}/build-${MINGW_CHOST}" |
| DESTDIR="${pkgdir}" ninja install |
| |
| install -Dm644 "${srcdir}/${_realname}-${pkgver}/COPYING" "${pkgdir}${MINGW_PREFIX}/share/licenses/${_realname}/COPYING" |
| } |
