| # Maintainer: Alexey Pavlov <alexpux@gmail.com> |
| # Maintainer: Chilledheart <rwindz0@gmail.com> |
| |
| _realname=libevent |
| pkgbase=mingw-w64-${_realname} |
| pkgname="${MINGW_PACKAGE_PREFIX}-${_realname}" |
| pkgver=2.1.12 |
| pkgrel=2 |
| pkgdesc="An event notification library (mingw-w64)" |
| arch=('any') |
| mingw_arch=('mingw32' 'mingw64' 'ucrt64' 'clang64' 'clang32') |
| url="https://libevent.org" |
| license=('BSD') |
| makedepends=("${MINGW_PACKAGE_PREFIX}-gcc" |
| "${MINGW_PACKAGE_PREFIX}-openssl") |
| optdepends=("${MINGW_PACKAGE_PREFIX}-python") |
| source=(https://github.com/${_realname}/${_realname}/releases/download/release-${pkgver}-stable/${_realname}-${pkgver}-stable.tar.gz |
| 'event2-02-win32.patch') |
| sha256sums=('92e6de1be9ec176428fd2367677e61ceffc2ee1cb119035037a27d346b0403bb' |
| 'e572ed628daba12915aaa5867b35ef1b0ca3ed3eb6e9759f97136dd8eab32c08') |
| |
| prepare() { |
| cd "${srcdir}/${_realname}-${pkgver}-stable" |
| |
| # to make transmission work, taken from: |
| # https://github.com/transmission/libevent/commit/72e50166aaa2c3b3c35e336039df7101bd418264 |
| patch -p1 -i ${srcdir}/event2-02-win32.patch |
| autoreconf -fiv |
| } |
| |
| build() { |
| [[ -d "${srcdir}/build-${MINGW_CHOST}" ]] && rm -rf "${srcdir}/build-${MINGW_CHOST}" |
| mkdir -p "${srcdir}/build-${MINGW_CHOST}" && cd "${srcdir}/build-${MINGW_CHOST}" |
| ../${_realname}-${pkgver}-stable/configure \ |
| --prefix=${MINGW_PREFIX} \ |
| --build=${MINGW_CHOST} \ |
| --host=${MINGW_CHOST} \ |
| --target=${MINGW_CHOST} \ |
| --sysconfdir=${MINGW_PREFIX}/etc |
| |
| make |
| } |
| |
| package() { |
| cd "${srcdir}/build-${MINGW_CHOST}" |
| make DESTDIR="${pkgdir}" install |
| |
| sed -s "s|$(cygpath -m ${MINGW_PREFIX})|${MINGW_PREFIX}|g" -i "${pkgdir}${MINGW_PREFIX}/lib/pkgconfig/${_realname}_openssl.pc" |
| } |
