| # Maintainer: Sarah Ottinger |
| |
| _realname=click |
| pkgbase=mingw-w64-python-${_realname} |
| pkgname=("${MINGW_PACKAGE_PREFIX}-python-${_realname}") |
| pkgver=8.0.1 |
| pkgrel=2 |
| pkgdesc='A simple wrapper around optparse for powerful command line utilities (mingw-w64)' |
| arch=('any') |
| mingw_arch=('mingw32' 'mingw64' 'ucrt64' 'clang64' 'clang32') |
| url="http://click.pocoo.org/" |
| license=('BSD') |
| depends=( |
| "${MINGW_PACKAGE_PREFIX}-python" |
| "${MINGW_PACKAGE_PREFIX}-python-colorama" |
| ) |
| makedepends=("${MINGW_PACKAGE_PREFIX}-python-setuptools") |
| source=("${_realname}-$pkgver.tar.gz::https://github.com/pallets/click/archive/${pkgver}.tar.gz") |
| sha512sums=('d93ec1d070dfa306733ee79893c64de9afcb0c7bf03d3f543dd697ef195f3a750828f77842a22886960a938740b92f0122962076ea52b911b87f7f75941a9032') |
| |
| prepare() { |
| cd "$srcdir" |
| rm -rf python-build-${CARCH} | true |
| cp -r "${_realname}-${pkgver}" "python-build-${CARCH}" |
| } |
| |
| build() { |
| msg "Python build for ${CARCH}" |
| cd "${srcdir}/python-build-${CARCH}" |
| ${MINGW_PREFIX}/bin/python setup.py build |
| } |
| |
| package() { |
| cd "${srcdir}/python-build-${CARCH}" |
| MSYS2_ARG_CONV_EXCL="--prefix=;--install-scripts=;--install-platlib=" \ |
| ${MINGW_PREFIX}/bin/python setup.py install --prefix=${MINGW_PREFIX} \ |
| --root="${pkgdir}" --optimize=1 --skip-build |
| install -Dm644 LICENSE.rst "${pkgdir}${MINGW_PREFIX}/share/licenses/python-${_realname}/LICENSE.rst" |
| } |
