| # Maintainer: Sarah Ottinger |
| |
| _realname=dephell-markers |
| pkgbase=mingw-w64-python-${_realname} |
| pkgname=("${MINGW_PACKAGE_PREFIX}-python-${_realname}") |
| pkgver=1.0.3 |
| pkgrel=1 |
| pkgdesc='Work with environment markers (PEP-496) (mingw-w64)' |
| arch=('any') |
| mingw_arch=('mingw32' 'mingw64' 'ucrt64' 'clang64' 'clang32') |
| url="https://github.com/dephell/dephell_markers" |
| license=('MIT') |
| depends=("${MINGW_PACKAGE_PREFIX}-python-dephell-specifier") |
| makedepends=("${MINGW_PACKAGE_PREFIX}-python-setuptools") |
| checkdepends=("${MINGW_PACKAGE_PREFIX}-python-pytest") |
| source=("https://files.pythonhosted.org/packages/source/${_realname:0:1}/${_realname//-/_}/${_realname//-/_}-${pkgver}.tar.gz") |
| sha256sums=('525e17914e705acf8652dd8681fccdec912432a747d8def4720f49416817f2d4') |
| |
| prepare() { |
| cd "$srcdir" |
| rm -rf python-build-${CARCH} | true |
| cp -r "${_realname//-/_}-$pkgver" "python-build-${CARCH}" |
| # pycache slipped into release tarballs |
| find . -name \*.pyc -delete |
| } |
| |
| build() { |
| msg "Python build for ${CARCH}" |
| cd "${srcdir}/python-build-${CARCH}" |
| ${MINGW_PREFIX}/bin/python setup.py build |
| } |
| |
| check() { |
| cd "${srcdir}/python-build-${CARCH}" |
| MSYS2_ARG_CONV_EXCL="--prefix=;--install-scripts=;--install-platlib=" \ |
| ${MINGW_PREFIX}/bin/python -m pytest || warning "Tests failed" |
| } |
| |
| package() { |
| cd "${srcdir}/python-build-${CARCH}" |
| MSYS2_ARG_CONV_EXCL="--prefix=;--install-scripts=;--install-platlib=" \ |
| ${MINGW_PREFIX}/bin/python setup.py install --prefix=${MINGW_PREFIX} \ |
| --root="${pkgdir}" --optimize=1 --skip-build |
| install -Dm644 LICENSE "${pkgdir}${MINGW_PREFIX}/share/licenses/python-${_realname}/LICENSE" |
| } |
