| # Maintainer: Frederic Wang <fred.wang@free.fr> |
| |
| _realname=idna |
| pkgbase=mingw-w64-python-${_realname} |
| pkgname=("${MINGW_PACKAGE_PREFIX}-python-${_realname}") |
| provides=("${MINGW_PACKAGE_PREFIX}-python3-${_realname}") |
| conflicts=("${MINGW_PACKAGE_PREFIX}-python3-${_realname}") |
| replaces=("${MINGW_PACKAGE_PREFIX}-python3-${_realname}") |
| pkgver=3.2 |
| pkgrel=1 |
| pkgdesc='Internationalized Domain Names in Applications (mingw-w64)' |
| url='https://github.com/kjd/idna' |
| license=('BSD-like') |
| arch=('any') |
| mingw_arch=('mingw32' 'mingw64' 'ucrt64' 'clang64' 'clang32' 'clangarm64') |
| depends=("${MINGW_PACKAGE_PREFIX}-python") |
| makedepends=("${MINGW_PACKAGE_PREFIX}-python-setuptools") |
| _dtoken="d8/82/28a51052215014efc07feac7330ed758702fc0581347098a81699b5281cb" |
| source=("https://pypi.io/packages/source/${_realname::1}/${_realname}/${_realname}-${pkgver}.tar.gz") |
| sha256sums=('467fbad99067910785144ce333826c71fb0e63a425657295239737f7ecd125f3') |
| |
| prepare() { |
| cd ${srcdir} |
| rm -rf python-build-${CARCH} |
| cp -r ${_realname}-${pkgver} python-build-${CARCH} |
| } |
| |
| build() { |
| msg "Python build for ${CARCH}" |
| cd "${srcdir}/python-build-${CARCH}" |
| ${MINGW_PREFIX}/bin/python setup.py build |
| } |
| |
| check() { |
| msg "Python test for ${CARCH}" |
| cd "${srcdir}/python-build-${CARCH}" |
| ${MINGW_PREFIX}/bin/python setup.py test |
| } |
| |
| package() { |
| cd "${srcdir}/python-build-${CARCH}" |
| |
| MSYS2_ARG_CONV_EXCL="--prefix=;--install-scripts=;--install-platlib=" \ |
| ${MINGW_PREFIX}/bin/python setup.py install --prefix=${MINGW_PREFIX} --root="${pkgdir}" --optimize=1 --skip-build |
| |
| install -Dm644 "${srcdir}/${_realname}-${pkgver}/LICENSE.md" "${pkgdir}${MINGW_PREFIX}/share/licenses/python-${_realname}/LICENSE" |
| } |
