| # Maintainer: @naveen521kk on Github, Naveen M K <naveen@syrusdark.website> |
| |
| _pyname=mapbox_earcut |
| _realname=mapbox-earcut |
| pkgbase=mingw-w64-${_realname} |
| pkgname=("${MINGW_PACKAGE_PREFIX}-${_realname}") |
| pkgver=0.12.10 |
| pkgrel=1 |
| pkgdesc="Python bindings for the mapbox earcut C++ polygon triangulation library. (mingw-w64)" |
| arch=('any') |
| mingw_arch=('mingw32' 'mingw64' 'ucrt64' 'clang64') |
| url='https://pypi.org/project/mapbox-earcut/' |
| license=('ISC') |
| depends=( |
| "${MINGW_PACKAGE_PREFIX}-pybind11" |
| "${MINGW_PACKAGE_PREFIX}-python" |
| "${MINGW_PACKAGE_PREFIX}-python-numpy" |
| ) |
| makedepends=("${MINGW_PACKAGE_PREFIX}-cmake" |
| "${MINGW_PACKAGE_PREFIX}-pybind11" |
| "${MINGW_PACKAGE_PREFIX}-python-setuptools" |
| "${MINGW_PACKAGE_PREFIX}-python-setuptools-scm") |
| source=( |
| "${_pyname}-${pkgver}.tar.gz::https://pypi.org/packages/source/${_pyname::1}/${_pyname}/${_pyname}-${pkgver}.tar.gz" |
| '0001-Add-MINGW-support.patch' |
| ) |
| sha256sums=('50d995673ac9ce8cb9abb7ab64b709d611c1d27557907e00b631b5272345c453' |
| '596c6a2e54a1699462d285250ca5f143e8f358442580addf5ee4a486194f3a93') |
| |
| prepare() { |
| rm -rf python-build-${CARCH} | true |
| cp -r "${_pyname}-${pkgver}" "python-build-${CARCH}" |
| cd "${srcdir}/python-build-${CARCH}" |
| patch -Np1 -i ${srcdir}/0001-Add-MINGW-support.patch |
| } |
| |
| build() { |
| msg "Python build for ${CARCH}" |
| cd "${srcdir}/python-build-${CARCH}" |
| ${MINGW_PREFIX}/bin/python setup.py build |
| } |
| |
| package() { |
| cd "${srcdir}/python-build-${CARCH}" |
| MSYS2_ARG_CONV_EXCL="--prefix=;--install-scripts=;--install-platlib=" \ |
| ${MINGW_PREFIX}/bin/python setup.py install --prefix=${MINGW_PREFIX} \ |
| --root="${pkgdir}" --optimize=1 --skip-build |
| install -Dm644 LICENSE.md "${pkgdir}${MINGW_PREFIX}/share/licenses/python-${_realname}/LICENSE" |
| } |
