| # Contributor: Runar Tenfjord < runar dot tenfjord at gmail dot com > |
| |
| _realname=numexpr |
| pkgbase=mingw-w64-python-${_realname} |
| pkgname=("${MINGW_PACKAGE_PREFIX}-python-$_realname") |
| provides=("${MINGW_PACKAGE_PREFIX}-python3-${_realname}") |
| conflicts=("${MINGW_PACKAGE_PREFIX}-python3-${_realname}") |
| replaces=("${MINGW_PACKAGE_PREFIX}-python3-${_realname}") |
| pkgver=2.7.3 |
| pkgrel=1 |
| pkgdesc="Fast numerical array expression evaluator for Python, NumPy, PyTables, pandas (mingw-w64)" |
| arch=('any') |
| mingw_arch=('mingw32' 'mingw64' 'ucrt64' 'clang64') |
| url="https://github.com/pydata/numexpr" |
| license=('MIT') |
| depends=("${MINGW_PACKAGE_PREFIX}-python-numpy") |
| makedepends=("${MINGW_PACKAGE_PREFIX}-python-setuptools" |
| "${MINGW_PACKAGE_PREFIX}-gcc") |
| source=("${_realname}-${pkgver}.tar.gz"::https://github.com/pydata/numexpr/archive/v${pkgver}.tar.gz) |
| sha256sums=('00d6b1518605afe0ed10417e0ff07123e5d531c02496c6eed7dd4b9923238e1e') |
| |
| prepare() { |
| cd "${srcdir}" |
| rm -rf python-build-${CARCH} | true |
| cp -r "${_realname}-${pkgver}" "python-build-${CARCH}" |
| } |
| |
| build() { |
| cd "${srcdir}/python-build-${CARCH}" |
| |
| MSYS2_ARG_CONV_EXCL="--prefix=;--install-scripts=;--install-platlib=" \ |
| ${MINGW_PREFIX}/bin/python setup.py build |
| } |
| |
| package() { |
| cd "${srcdir}/python-build-${CARCH}" |
| |
| MSYS2_ARG_CONV_EXCL="--prefix=;--install-scripts=;--install-platlib=" \ |
| ${MINGW_PREFIX}/bin/python setup.py install --skip-build \ |
| --prefix=${MINGW_PREFIX} --root=${pkgdir} --optimize=1 |
| |
| install -Dm644 LICENSE.txt \ |
| "${pkgdir}${MINGW_PREFIX}/share/licenses/python-${_realname}/LICENSE.txt" |
| } |
