| # Maintainer: Sarah Ottinger |
| |
| _realname=pytest-timeout |
| pkgbase=mingw-w64-python-${_realname} |
| pkgname=("${MINGW_PACKAGE_PREFIX}-python-${_realname}") |
| pkgver=1.4.2 |
| pkgrel=2 |
| pkgdesc='py.test plugin to abort hanging tests (mingw-w64)' |
| arch=('any') |
| mingw_arch=('mingw32' 'mingw64' 'ucrt64' 'clang64' 'clang32') |
| url="https://bitbucket.org/pytest-dev/pytest-timeout" |
| license=('MIT') |
| depends=("${MINGW_PACKAGE_PREFIX}-python-pytest") |
| makedepends=("${MINGW_PACKAGE_PREFIX}-python-setuptools") |
| source=("https://github.com/pytest-dev/pytest-timeout/archive/$pkgver/${_realname}-$pkgver.tar.gz") |
| sha512sums=('062ce6c832a7139874ad8f165818c2a7d9cef4a2fe2c53a6c37d4f0a060cf920204f1d2d255e4d31953c0da268e708c1d305f362cd6d0ea103bc101ffb51b098') |
| |
| prepare() { |
| cd "$srcdir" |
| rm -rf python-build-${CARCH} | true |
| cp -r "${_realname}-${pkgver}" "python-build-${CARCH}" |
| } |
| |
| build() { |
| msg "Python build for ${CARCH}" |
| cd "${srcdir}/python-build-${CARCH}" |
| ${MINGW_PREFIX}/bin/python setup.py build |
| } |
| |
| package() { |
| cd "${srcdir}/python-build-${CARCH}" |
| MSYS2_ARG_CONV_EXCL="--prefix=;--install-scripts=;--install-platlib=" \ |
| ${MINGW_PREFIX}/bin/python setup.py install --prefix=${MINGW_PREFIX} \ |
| --root="${pkgdir}" --optimize=1 --skip-build |
| install -Dm644 LICENSE "${pkgdir}${MINGW_PREFIX}/share/licenses/python-${_realname}/LICENSE" |
| } |
