| # Maintainer: Christoph Reiter <reiter.christoph@gmail.com> |
| |
| _realname=sassc |
| pkgbase=mingw-w64-${_realname} |
| pkgname="${MINGW_PACKAGE_PREFIX}-${_realname}" |
| pkgver=3.6.2 |
| pkgrel=1 |
| pkgdesc="C implementation of Sass CSS preprocessor (mingw-w64)" |
| arch=('any') |
| mingw_arch=('mingw32' 'mingw64' 'ucrt64' 'clang64' 'clang32') |
| url="http://libsass.org/" |
| license=("MIT") |
| depends=("${MINGW_PACKAGE_PREFIX}-libsass") |
| source=("${_realname}-${pkgver}.tar.gz::https://github.com/sass/${_realname}/archive/${pkgver}.tar.gz") |
| sha256sums=('608dc9002b45a91d11ed59e352469ecc05e4f58fc1259fc9a9f5b8f0f8348a03') |
| |
| prepare() { |
| cd "${srcdir}/${_realname}-${pkgver}" |
| autoreconf -vfi |
| } |
| |
| build() { |
| [[ -d "${srcdir}/build-${MINGW_CHOST}" ]] && rm -rf "${srcdir}/build-${MINGW_CHOST}" |
| mkdir -p "${srcdir}/build-${MINGW_CHOST}" && cd "${srcdir}/build-${MINGW_CHOST}" |
| |
| ../${_realname}-${pkgver}/configure \ |
| --prefix=${MINGW_PREFIX} \ |
| --build=${MINGW_CHOST} \ |
| --host=${MINGW_CHOST} \ |
| --target=${MINGW_CHOST} |
| |
| make |
| } |
| |
| package() { |
| cd "${srcdir}/build-${MINGW_CHOST}" |
| |
| make DESTDIR="${pkgdir}" install |
| |
| install -Dm644 "${srcdir}/${_realname}-${pkgver}/LICENSE" "${pkgdir}${MINGW_PREFIX}/share/licenses/${_realname}/LICENSE" |
| } |
