| # Maintainer (MSYS2): Michael Hansen <zrax0111@gmail.com> |
| |
| _variant=-${KF5_VARIANT:-shared} |
| source "$(dirname ${BASH_SOURCE[0]})"/../mingw-w64-PKGBUILD-common/kde-frameworks5 |
| _kde_f5_init_package "${_variant}" "sonnet" |
| pkgver=5.83.0 |
| pkgrel=1 |
| arch=('any') |
| mingw_arch=('mingw32' 'mingw64' 'ucrt64' 'clang64') |
| pkgdesc="Spell checking framework for Qt (mingw-w64-qt5${_namesuff})" |
| license=('LGPL') |
| makedepends=("${MINGW_PACKAGE_PREFIX}-extra-cmake-modules>=${pkgver}" |
| "${MINGW_PACKAGE_PREFIX}-hunspell" |
| "${MINGW_PACKAGE_PREFIX}-aspell" |
| "${MINGW_PACKAGE_PREFIX}-ninja") |
| depends=() |
| _kde_f5_add_depends "${_variant}" "${MINGW_PACKAGE_PREFIX}-qt5${_namesuff}" |
| optdepends=("${MINGW_PACKAGE_PREFIX}-hunspell: spell checking via hunspell" |
| "${MINGW_PACKAGE_PREFIX}-aspell: spell checking via aspell") |
| groups=("${MINGW_PACKAGE_PREFIX}-kf5") |
| source=("https://download.kde.org/stable/frameworks/${pkgver%.*}/${_basename}-${pkgver}.tar.xz"{,.sig} |
| 001-drop-pre-win7-support.patch) |
| sha256sums=('aad844fcfa4c9acb1a634528f35c56ec906e8a71c07f40dd1a748ac51e96502f' |
| 'SKIP' |
| '9e546a6881b470f3a1030b45604058525374d0e57839f12dfd25c78397012f61') |
| validpgpkeys=('53E6B47B45CEA3E0D5B7457758D0EE648A48B3BB') # David Faure <faure@kde.org> |
| |
| prepare() { |
| mkdir -p build-${CARCH}${_variant} |
| |
| cd "${_basename}-${pkgver}" |
| patch -p1 -i ${srcdir}/001-drop-pre-win7-support.patch |
| } |
| |
| build() { |
| local -a extra_config |
| cd build-${CARCH}${_variant} |
| if [ "${_variant}" = "-static" ]; then |
| extra_config+=( -DBUILD_SHARED_LIBS=NO ) |
| fi |
| |
| _kde_f5_build_env |
| ${MINGW_PREFIX}/bin/cmake.exe \ |
| -G "Ninja" \ |
| -DCMAKE_BUILD_TYPE=$(_kde_f5_CMAKE_BUILD_TYPE) \ |
| "${_kde_f5_KDE_INSTALL_DIRS[@]}" \ |
| -DBUILD_QCH=OFF \ |
| -DBUILD_TESTING=OFF \ |
| -DECM_DIR=${MINGW_PREFIX}/share/ECM \ |
| "${extra_config[@]}" \ |
| ../${_basename}-${pkgver} |
| |
| ${MINGW_PREFIX}/bin/cmake.exe --build ./ |
| } |
| |
| package() { |
| cd build-${CARCH}${_variant} |
| DESTDIR="${pkgdir}" ${MINGW_PREFIX}/bin/cmake.exe --build ./ --target install |
| } |
