| # Maintainer: Alexey Pavlov <alexpux@gmail.com> |
| |
| _realname=zziplib |
| pkgbase=mingw-w64-${_realname} |
| pkgname="${MINGW_PACKAGE_PREFIX}-${_realname}" |
| pkgver=0.13.72 |
| pkgrel=3 |
| pkgdesc="A lightweight library that offers the ability to easily extract data from files archived in a single zip file (mingw-w64)" |
| arch=('any') |
| mingw_arch=('mingw32' 'mingw64' 'ucrt64' 'clang64' 'clang32') |
| url="https://zziplib.sourceforge.net/" |
| license=("LGPL, MPL") |
| makedepends=("${MINGW_PACKAGE_PREFIX}-pkg-config" |
| "${MINGW_PACKAGE_PREFIX}-python" |
| "${MINGW_PACKAGE_PREFIX}-cmake" |
| "${MINGW_PACKAGE_PREFIX}-ninja" |
| "zip") |
| depends=("${MINGW_PACKAGE_PREFIX}-zlib") |
| optdepends=("${MINGW_PACKAGE_PREFIX}-SDL: SDL_rwops for ZZipLib") |
| options=('strip' '!debug' 'staticlibs') |
| source=("${_realname}-${pkgver}.tar.gz"::"https://github.com/gdraheim/zziplib/archive/v${pkgver}.tar.gz" |
| "010-extern.patch" |
| "020-cmake-install-pkgconfig.patch::https://github.com/gdraheim/zziplib/commit/eaab833a6017e1faeba6a017c050ac000d54b290.patch" |
| "030-cmake-remove-libs-number.patch") |
| sha256sums=('93ef44bf1f1ea24fc66080426a469df82fa631d13ca3b2e4abaeab89538518dc' |
| 'ea4a2a6c49e9a71d89ea88e33bf855604d6ea3055f0f9cecde2898a02044811f' |
| '5e05fd37ac12ef3be88a38a066d70a507a638f16f1703d8ab3b2e9af764c3b55' |
| '79d55dbc9b4f4c9f018b8569e14d52ba94087abfa89b8da624707d957ef73042') |
| |
| prepare() { |
| cd "${srcdir}/${_realname}-${pkgver}" |
| |
| patch -p1 -i ${srcdir}/010-extern.patch |
| patch -p1 -i ${srcdir}/020-cmake-install-pkgconfig.patch |
| patch -p1 -i ${srcdir}/030-cmake-remove-libs-number.patch |
| } |
| |
| build() { |
| declare -a _extra_config |
| if check_option "debug" "n"; then |
| _extra_config+=("-DCMAKE_BUILD_TYPE=Release") |
| else |
| _extra_config+=("-DCMAKE_BUILD_TYPE=Debug") |
| fi |
| |
| echo "Building static library" |
| [[ -d "${srcdir}/build-${CARCH}-static" ]] && rm -rf "${srcdir}/build-${CARCH}-static" |
| mkdir -p "${srcdir}/build-${CARCH}-static" && cd "${srcdir}/build-${CARCH}-static" |
| |
| MSYS2_ARG_CONV_EXCL="-DCMAKE_INSTALL_PREFIX=" \ |
| ${MINGW_PREFIX}/bin/cmake.exe \ |
| -G'Ninja' \ |
| -DCMAKE_INSTALL_PREFIX=${MINGW_PREFIX} \ |
| "${_extra_config[@]}" \ |
| -DBUILD_SHARED_LIBS=OFF \ |
| -DBUILD_STATIC_LIBS=ON \ |
| ../${_realname}-${pkgver} |
| |
| ${MINGW_PREFIX}/bin/cmake.exe --build ./ |
| |
| echo "Building shared library" |
| [[ -d "${srcdir}/build-${CARCH}-shared" ]] && rm -rf "${srcdir}/build-${CARCH}-shared" |
| mkdir -p "${srcdir}/build-${CARCH}-shared" && cd "${srcdir}/build-${CARCH}-shared" |
| |
| MSYS2_ARG_CONV_EXCL="-DCMAKE_INSTALL_PREFIX=" \ |
| ${MINGW_PREFIX}/bin/cmake.exe \ |
| -G'Ninja' \ |
| -DCMAKE_INSTALL_PREFIX=${MINGW_PREFIX} \ |
| "${_extra_config[@]}" \ |
| -DBUILD_SHARED_LIBS=ON \ |
| -DBUILD_STATIC_LIBS=OFF \ |
| ../${_realname}-${pkgver} |
| |
| ${MINGW_PREFIX}/bin/cmake.exe --build ./ |
| } |
| |
| package() { |
| cd "${srcdir}/build-${CARCH}-static" |
| DESTDIR="${pkgdir}" ${MINGW_PREFIX}/bin/cmake.exe --build ./ --target install |
| |
| cd "${srcdir}/build-${CARCH}-shared" |
| DESTDIR="${pkgdir}" ${MINGW_PREFIX}/bin/cmake.exe --build ./ --target install |
| |
| install -Dm644 "${srcdir}/${_realname}-${pkgver}/COPYING.LIB" \ |
| "${pkgdir}${MINGW_PREFIX}/share/licenses/${_realname}/COPYING.LIB" |
| } |