| # Maintainer: Alexey Pavlov <alexpux@gmail.com> |
| |
| _realname=gedit |
| pkgbase=mingw-w64-${_realname} |
| pkgname="${MINGW_PACKAGE_PREFIX}-${_realname}" |
| pkgver=3.38.1 |
| pkgrel=1 |
| arch=('any') |
| mingw_arch=('mingw32' 'mingw64' 'ucrt64' 'clang64') |
| pkgdesc="A text editor for GNOME (mingw-w64)" |
| depends=("${MINGW_PACKAGE_PREFIX}-adwaita-icon-theme" |
| "${MINGW_PACKAGE_PREFIX}-appstream-glib" |
| "${MINGW_PACKAGE_PREFIX}-gsettings-desktop-schemas" |
| "${MINGW_PACKAGE_PREFIX}-gtksourceview4" |
| "${MINGW_PACKAGE_PREFIX}-gtk3" |
| "${MINGW_PACKAGE_PREFIX}-libpeas" |
| "${MINGW_PACKAGE_PREFIX}-python-gobject" |
| "${MINGW_PACKAGE_PREFIX}-gspell" |
| "${MINGW_PACKAGE_PREFIX}-gobject-introspection-runtime" |
| "${MINGW_PACKAGE_PREFIX}-tepl5") |
| makedepends=("${MINGW_PACKAGE_PREFIX}-gcc" |
| "${MINGW_PACKAGE_PREFIX}-gobject-introspection" |
| "${MINGW_PACKAGE_PREFIX}-gtk-doc" |
| "${MINGW_PACKAGE_PREFIX}-gettext" |
| "${MINGW_PACKAGE_PREFIX}-itstool" |
| "${MINGW_PACKAGE_PREFIX}-meson" |
| "${MINGW_PACKAGE_PREFIX}-ninja" |
| "${MINGW_PACKAGE_PREFIX}-pkg-config" |
| "${MINGW_PACKAGE_PREFIX}-python" |
| "${MINGW_PACKAGE_PREFIX}-vala" |
| "${MINGW_PACKAGE_PREFIX}-yelp-tools") |
| options=('strip' 'staticlibs') |
| license=("GPL") |
| url="https://www.gnome.org" |
| install=${_realname}-${CARCH}.install |
| source=(https://download.gnome.org/sources/${_realname}/${pkgver%.*}/${_realname}-${pkgver}.tar.xz |
| "0001-workaround-no-delayed-loading.patch") |
| sha256sums=('0053853d2cd59cad8a1662f5b4fdcfab47b4c0940063bacd6790a9948642844d' |
| '96f71347451a4443e29135853abea2260e3d4cc32b1691569f2669f18720dd52') |
| |
| prepare() { |
| cd "${srcdir}"/${_realname}-${pkgver} |
| |
| # gedit requires delayed loading which isn't supported by meson |
| # yet, so move the lib to /bin. |
| # https://github.com/mesonbuild/meson/issues/5093 |
| patch -Np1 -i "${srcdir}"/0001-workaround-no-delayed-loading.patch |
| } |
| |
| build() { |
| [[ -d build-${MINGW_CHOST} ]] && rm -rf build-${MINGW_CHOST} |
| mkdir -p build-${MINGW_CHOST} && cd build-${MINGW_CHOST} |
| |
| MSYS2_ARG_CONV_EXCL="--prefix=" \ |
| ${MINGW_PREFIX}/bin/meson \ |
| --prefix=${MINGW_PREFIX} \ |
| --buildtype=plain \ |
| "../${_realname}-${pkgver}" |
| |
| ninja |
| } |
| |
| package() { |
| cd "${srcdir}/build-${MINGW_CHOST}" |
| DESTDIR="${pkgdir}" ninja install |
| |
| install -Dm644 "${srcdir}/${_realname}-${pkgver}/COPYING" "${pkgdir}${MINGW_PREFIX}/share/licenses/${_realname}/COPYING" |
| } |
