| # Maintainer: Sarah Ottinger <schalaalexiazeal@gmail.com> |
| |
| _realname=ftfy |
| pkgbase=mingw-w64-python-${_realname} |
| pkgname=("${MINGW_PACKAGE_PREFIX}-python-${_realname}") |
| pkgver=6.0.3 |
| pkgrel=1 |
| pkgdesc='Fixes some problems with Unicode text after the fact (mingw-w64)' |
| arch=('any') |
| mingw_arch=('mingw32' 'mingw64' 'ucrt64' 'clang64' 'clang32') |
| url="https://github.com/LuminosoInsight/python-ftfy" |
| license=('MIT') |
| depends=("${MINGW_PACKAGE_PREFIX}-python-wcwidth") |
| makedepends=("${MINGW_PACKAGE_PREFIX}-python-setuptools") |
| source=("https://files.pythonhosted.org/packages/source/f/${_realname}/${_realname}-${pkgver}.tar.gz") |
| sha256sums=('ba71121a9c8d7790d3e833c6c1021143f3e5c4118293ec3afb5d43ed9ca8e72b') |
| |
| prepare() { |
| cd "$srcdir" |
| rm -rf python-build-${CARCH} | true |
| cp -r "${_realname}-${pkgver}" "python-build-${CARCH}" |
| } |
| |
| build() { |
| msg "Python build for ${CARCH}" |
| cd "${srcdir}/python-build-${CARCH}" |
| ${MINGW_PREFIX}/bin/python setup.py build |
| } |
| |
| package() { |
| cd "${srcdir}/python-build-${CARCH}" |
| MSYS2_ARG_CONV_EXCL="--prefix=;--install-scripts=;--install-platlib=" \ |
| ${MINGW_PREFIX}/bin/python setup.py install --prefix=${MINGW_PREFIX} \ |
| --root="${pkgdir}" --optimize=1 --skip-build |
| install -Dm644 LICENSE.txt "${pkgdir}${MINGW_PREFIX}/share/licenses/python-${_realname}/LICENSE.txt" |
| |
| for _f in "${pkgdir}${MINGW_PREFIX}"/bin/*-script.py; do |
| sed -e '1 { s/^#!.*$// }' -i ${_f} |
| done |
| } |
