| # Maintainer: Sarah Ottinger |
| |
| _realname=pip-tools |
| pkgbase=mingw-w64-python-${_realname} |
| pkgname=("${MINGW_PACKAGE_PREFIX}-python-${_realname}") |
| pkgver=6.1.0 |
| pkgrel=1 |
| pkgdesc='A set of tools to keep your pinned Python dependencies fresh. (mingw-w64)' |
| arch=('any') |
| mingw_arch=('mingw32' 'mingw64' 'ucrt64' 'clang64' 'clang32') |
| url="https://github.com/jazzband/pip-tools/" |
| license=('BSD') |
| depends=("${MINGW_PACKAGE_PREFIX}-python-click>=7" "${MINGW_PACKAGE_PREFIX}-python-pep517" "${MINGW_PACKAGE_PREFIX}-python-pip>=20.3") |
| makedepends=("${MINGW_PACKAGE_PREFIX}-python-setuptools-scm") |
| source=("https://files.pythonhosted.org/packages/source/${_realname::1}/${_realname}/${_realname}-${pkgver}.tar.gz") |
| sha256sums=('400bf77e29cca48c31abc210042932bb52dcc138ef4ea4d52c5db429aa8ae6ee') |
| |
| prepare() { |
| cd "$srcdir" |
| rm -rf python-build-${CARCH} | true |
| cp -r "${_realname}-$pkgver" "python-build-${CARCH}" |
| } |
| |
| build() { |
| msg "Python build for ${CARCH}" |
| cd "${srcdir}/python-build-${CARCH}" |
| ${MINGW_PREFIX}/bin/python setup.py build |
| } |
| |
| package() { |
| cd "${srcdir}/python-build-${CARCH}" |
| MSYS2_ARG_CONV_EXCL="--prefix=;--install-scripts=;--install-platlib=" \ |
| ${MINGW_PREFIX}/bin/python setup.py install --prefix=${MINGW_PREFIX} \ |
| --root="${pkgdir}" --optimize=1 --skip-build |
| install -Dm644 LICENSE "${pkgdir}${MINGW_PREFIX}/share/licenses/python-${_realname}/LICENSE" |
| |
| for _f in "${pkgdir}${MINGW_PREFIX}"/bin/*-script.py; do |
| sed -e '1 { s/^#!.*$// }' -i ${_f} |
| done |
| } |
