| # Maintainer: Sarah Ottinger |
| |
| _realname=sounddevice |
| pkgbase=mingw-w64-python-${_realname} |
| pkgname=("${MINGW_PACKAGE_PREFIX}-python-${_realname}") |
| pkgver=0.4.1 |
| pkgrel=1 |
| pkgdesc='Play and Record Sound with Python (mingw-w64)' |
| arch=('any') |
| mingw_arch=('mingw32' 'mingw64' 'ucrt64' 'clang64' 'clang32') |
| url="https://python-sounddevice.rtfd.io/" |
| license=('MIT') |
| depends=("${MINGW_PACKAGE_PREFIX}-portaudio" "${MINGW_PACKAGE_PREFIX}-python-cffi") |
| makedepends=("${MINGW_PACKAGE_PREFIX}-python-setuptools") |
| optdepends=("${MINGW_PACKAGE_PREFIX}-python-numpy: to play back and record NumPy arrays") |
| source=("https://files.pythonhosted.org/packages/source/${_realname:0:1}/${_realname}/${_realname}-${pkgver}.tar.gz") |
| sha256sums=('f21978921186c0c7183af032fab77b735d824f3e926d76adb3fd0912e289ce0b') |
| |
| prepare() { |
| cd "$srcdir" |
| rm -rf python-build-${CARCH} | true |
| cp -r "${_realname}-$pkgver" "python-build-${CARCH}" |
| } |
| |
| build() { |
| msg "Python build for ${CARCH}" |
| cd "${srcdir}/python-build-${CARCH}" |
| ${MINGW_PREFIX}/bin/python setup.py build |
| } |
| |
| package() { |
| cd "${srcdir}/python-build-${CARCH}" |
| MSYS2_ARG_CONV_EXCL="--prefix=;--install-scripts=;--install-platlib=" \ |
| ${MINGW_PREFIX}/bin/python setup.py install --prefix=${MINGW_PREFIX} \ |
| --root="${pkgdir}" --optimize=1 --skip-build |
| install -Dm644 LICENSE "${pkgdir}${MINGW_PREFIX}/share/licenses/python-${_realname}/LICENSE" |
| } |
