| /**************************************************************************** |
| ** |
| ** Copyright (C) 2018 The Qt Company Ltd. |
| ** Contact: https://www.qt.io/licensing/ |
| ** |
| ** This file is part of the examples of the Qt Toolkit. |
| ** |
| ** $QT_BEGIN_LICENSE:BSD$ |
| ** Commercial License Usage |
| ** Licensees holding valid commercial Qt licenses may use this file in |
| ** accordance with the commercial license agreement provided with the |
| ** Software or, alternatively, in accordance with the terms contained in |
| ** a written agreement between you and The Qt Company. For licensing terms |
| ** and conditions see https://www.qt.io/terms-conditions. For further |
| ** information use the contact form at https://www.qt.io/contact-us. |
| ** |
| ** BSD License Usage |
| ** Alternatively, you may use this file under the terms of the BSD license |
| ** as follows: |
| ** |
| ** "Redistribution and use in source and binary forms, with or without |
| ** modification, are permitted provided that the following conditions are |
| ** met: |
| ** * Redistributions of source code must retain the above copyright |
| ** notice, this list of conditions and the following disclaimer. |
| ** * Redistributions in binary form must reproduce the above copyright |
| ** notice, this list of conditions and the following disclaimer in |
| ** the documentation and/or other materials provided with the |
| ** distribution. |
| ** * Neither the name of The Qt Company Ltd nor the names of its |
| ** contributors may be used to endorse or promote products derived |
| ** from this software without specific prior written permission. |
| ** |
| ** |
| ** THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS |
| ** "AS IS" AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT |
| ** LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR |
| ** A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE COPYRIGHT |
| ** OWNER OR CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL, |
| ** SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT |
| ** LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE, |
| ** DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY |
| ** THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT |
| ** (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE |
| ** OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE." |
| ** |
| ** $QT_END_LICENSE$ |
| ** |
| ****************************************************************************/ |
| |
| import QtQuick 2.0 |
| import QtQuick.Window 2.0 |
| import QtWebEngine 1.7 |
| import QtQuick.Controls 2.4 |
| import QtQuick.Layouts 1.11 |
| |
| ApplicationWindow { |
| id: window |
| visible: true |
| width: 800 |
| height: 600 |
| title: qsTr("WebEngineAction Example") |
| |
| header: ToolBar { |
| RowLayout { |
| anchors.fill: parent |
| |
| ToolButton { |
| property int itemAction: WebEngineView.Back |
| text: webEngineView.action(itemAction).text |
| enabled: webEngineView.action(itemAction).enabled |
| onClicked: webEngineView.action(itemAction).trigger() |
| icon.name: webEngineView.action(itemAction).iconName |
| display: AbstractButton.TextUnderIcon |
| } |
| |
| ToolButton { |
| property int itemAction: WebEngineView.Forward |
| text: webEngineView.action(itemAction).text |
| enabled: webEngineView.action(itemAction).enabled |
| onClicked: webEngineView.action(itemAction).trigger() |
| icon.name: webEngineView.action(itemAction).iconName |
| display: AbstractButton.TextUnderIcon |
| } |
| |
| ToolButton { |
| property int itemAction: webEngineView.loading ? WebEngineView.Stop : WebEngineView.Reload |
| text: webEngineView.action(itemAction).text |
| enabled: webEngineView.action(itemAction).enabled |
| onClicked: webEngineView.action(itemAction).trigger() |
| icon.name: webEngineView.action(itemAction).iconName |
| display: AbstractButton.TextUnderIcon |
| } |
| |
| TextField { |
| Layout.fillWidth: true |
| |
| text: webEngineView.url |
| selectByMouse: true |
| onEditingFinished: webEngineView.url = text |
| } |
| |
| ToolButton { |
| id: settingsButton |
| text: "Settings" |
| icon.name: "settings-configure" |
| display: AbstractButton.TextUnderIcon |
| onClicked: settingsMenu.open() |
| checked: settingsMenu.visible |
| |
| Menu { |
| id: settingsMenu |
| y: settingsButton.height |
| |
| MenuItem { |
| id: customContextMenuOption |
| checkable: true |
| checked: true |
| |
| text: "Custom context menu" |
| } |
| } |
| } |
| } |
| } |
| |
| WebEngineView { |
| id: webEngineView |
| url: "https://qt.io" |
| anchors.fill: parent |
| |
| Component.onCompleted: { |
| profile.downloadRequested.connect(function(download){ |
| download.accept(); |
| }) |
| } |
| |
| property Menu contextMenu: Menu { |
| Repeater { |
| model: [ |
| WebEngineView.Back, |
| WebEngineView.Forward, |
| WebEngineView.Reload, |
| WebEngineView.SavePage, |
| WebEngineView.Copy, |
| WebEngineView.Paste, |
| WebEngineView.Cut |
| ] |
| MenuItem { |
| text: webEngineView.action(modelData).text |
| enabled: webEngineView.action(modelData).enabled |
| onClicked: webEngineView.action(modelData).trigger() |
| icon.name: webEngineView.action(modelData).iconName |
| display: MenuItem.TextBesideIcon |
| } |
| } |
| } |
| |
| onContextMenuRequested: function(request) { |
| if (customContextMenuOption.checked) { |
| request.accepted = true; |
| contextMenu.popup(); |
| } |
| } |
| } |
| } |