qt-everywhere-src-5.15.1/qtdeclarative/examples/quick/delegatechooser/delegatechooser.qml

/****************************************************************************
**
** Copyright (C) 2018 The Qt Company Ltd.
** Contact: https://www.qt.io/licensing/
**
** This file is part of the examples of the Qt Toolkit.
**
** $QT_BEGIN_LICENSE:BSD$
** Commercial License Usage
** Licensees holding valid commercial Qt licenses may use this file in
** accordance with the commercial license agreement provided with the
** Software or, alternatively, in accordance with the terms contained in
** a written agreement between you and The Qt Company. For licensing terms
** and conditions see https://www.qt.io/terms-conditions. For further
** information use the contact form at https://www.qt.io/contact-us.
**
** BSD License Usage
** Alternatively, you may use this file under the terms of the BSD license
** as follows:
**
** "Redistribution and use in source and binary forms, with or without
** modification, are permitted provided that the following conditions are
** met:
**   * Redistributions of source code must retain the above copyright
**     notice, this list of conditions and the following disclaimer.
**   * Redistributions in binary form must reproduce the above copyright
**     notice, this list of conditions and the following disclaimer in
**     the documentation and/or other materials provided with the
**     distribution.
**   * Neither the name of The Qt Company Ltd nor the names of its
**     contributors may be used to endorse or promote products derived
**     from this software without specific prior written permission.
**
**
** THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS
** "AS IS" AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT
** LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR
** A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE COPYRIGHT
** OWNER OR CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL,
** SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT
** LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE,
** DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY
** THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT
** (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE
** OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE."
**
** $QT_END_LICENSE$
**
****************************************************************************/

import QtQuick 2.12
import QtQml.Models 2.12
import QtQuick.Layouts 1.12
import Qt.labs.qmlmodels 1.0

Rectangle {
    visible: true
    width: 640
    height: 640

    ListModel {
        id: listModel
        ListElement { dataType: "rect"; color: "green" }
        ListElement { dataType: "image"; source: "../shared/images/qt-logo.png" }
        ListElement { dataType: "rect"; color: "green" }
        ListElement { dataType: "image"; source: "../shared/images/qt-logo.png" }
        ListElement { dataType: "rect"; color: "blue" }
        ListElement { dataType: "rect"; color: "blue" }
        ListElement { dataType: "rect"; color: "blue" }
        ListElement { dataType: "rect"; color: "blue" }
        ListElement { dataType: "rect"; color: "blue" }
        ListElement { dataType: "rect"; color: "blue" }
    }

    ListModel {
        id: listModel2
        ListElement { dataType: "rect"; color: "blue" }
        ListElement { dataType: "rect"; color: "blue" }
        ListElement { dataType: "rect"; color: "green" }
        ListElement { dataType: "image"; source: "../shared/images/qt-logo.png" }
        ListElement { dataType: "rect"; color: "green" }
        ListElement { dataType: "image"; source: "../shared/images/qt-logo.png" }
        ListElement { dataType: "rect"; color: "blue" }
        ListElement { dataType: "rect"; color: "lightsteelblue" }
        ListElement { dataType: "rect"; color: "fuchsia" }
        ListElement { dataType: "rect"; color: "lime" }
    }

    DelegateChooser {
        id: fancyDelegate
        role: "dataType"
        DelegateChoice {
            roleValue: "rect"
            delegate: DelegateChooser {
                DelegateChoice {
                    row: 0
                    Rectangle {
                        width: parent.width
                        height: 50
                        color: "red"
                        border.color: "black"
                        border.width: 1
                    }
                }
                DelegateChoice {
                    Rectangle {
                        width: parent.width
                        height: 50
                        color: model.color
                        border.color: "black"
                        border.width: 1
                    }
                }
            }
        }
        DelegateChoice {
            roleValue: "image"
            delegate: Image {
                width: parent.width
                height: 100
                source: model.source
                fillMode: Image.PreserveAspectFit
            }
        }
    }

    Item {
        anchors.fill: parent
        id: ite
        RowLayout {
            ListView {
                Layout.preferredHeight: ite.height
                Layout.preferredWidth: ite.width * 0.5
                model: listModel
                delegate: fancyDelegate
            }
            ListView {
                Layout.preferredHeight: ite.height
                Layout.preferredWidth: ite.width * 0.5
                model: listModel2
                delegate: fancyDelegate
            }
        }
    }
}