| /**************************************************************************** |
| ** |
| ** Copyright (C) 2017 The Qt Company Ltd. |
| ** Contact: https://www.qt.io/licensing/ |
| ** |
| ** This file is part of the documentation of the Qt Toolkit. |
| ** |
| ** $QT_BEGIN_LICENSE:FDL$ |
| ** Commercial License Usage |
| ** Licensees holding valid commercial Qt licenses may use this file in |
| ** accordance with the commercial license agreement provided with the |
| ** Software or, alternatively, in accordance with the terms contained in |
| ** a written agreement between you and The Qt Company. For licensing terms |
| ** and conditions see https://www.qt.io/terms-conditions. For further |
| ** information use the contact form at https://www.qt.io/contact-us. |
| ** |
| ** GNU Free Documentation License Usage |
| ** Alternatively, this file may be used under the terms of the GNU Free |
| ** Documentation License version 1.3 as published by the Free Software |
| ** Foundation and appearing in the file included in the packaging of |
| ** this file. Please review the following information to ensure |
| ** the GNU Free Documentation License version 1.3 requirements |
| ** will be met: https://www.gnu.org/licenses/fdl-1.3.html. |
| ** $QT_END_LICENSE$ |
| ** |
| ****************************************************************************/ |
| |
| //! [file] |
| import QtQuick 2.12 |
| import QtQuick.Controls 2.12 |
| |
| DelayButton { |
| id: control |
| checked: true |
| text: qsTr("Delay\nButton") |
| |
| contentItem: Text { |
| text: control.text |
| font: control.font |
| opacity: enabled ? 1.0 : 0.3 |
| color: "white" |
| horizontalAlignment: Text.AlignHCenter |
| verticalAlignment: Text.AlignVCenter |
| elide: Text.ElideRight |
| } |
| |
| background: Rectangle { |
| implicitWidth: 100 |
| implicitHeight: 100 |
| opacity: enabled ? 1 : 0.3 |
| color: control.down ? "#17a81a" : "#21be2b" |
| radius: size / 2 |
| |
| readonly property real size: Math.min(control.width, control.height) |
| width: size |
| height: size |
| anchors.centerIn: parent |
| |
| Canvas { |
| id: canvas |
| anchors.fill: parent |
| |
| Connections { |
| target: control |
| function onProgressChanged() { canvas.requestPaint(); } |
| } |
| |
| onPaint: { |
| var ctx = getContext("2d") |
| ctx.clearRect(0, 0, width, height) |
| ctx.strokeStyle = "white" |
| ctx.lineWidth = parent.size / 20 |
| ctx.beginPath() |
| var startAngle = Math.PI / 5 * 3 |
| var endAngle = startAngle + control.progress * Math.PI / 5 * 9 |
| ctx.arc(width / 2, height / 2, width / 2 - ctx.lineWidth / 2 - 2, startAngle, endAngle) |
| ctx.stroke() |
| } |
| } |
| } |
| } |
| //! [file] |