| /**************************************************************************** |
| ** |
| ** Copyright (C) 2017 Klaralvdalens Datakonsult AB (KDAB). |
| ** Contact: https://www.qt.io/licensing/ |
| ** |
| ** This file is part of the Qt3D module of the Qt Toolkit. |
| ** |
| ** $QT_BEGIN_LICENSE:BSD$ |
| ** Commercial License Usage |
| ** Licensees holding valid commercial Qt licenses may use this file in |
| ** accordance with the commercial license agreement provided with the |
| ** Software or, alternatively, in accordance with the terms contained in |
| ** a written agreement between you and The Qt Company. For licensing terms |
| ** and conditions see https://www.qt.io/terms-conditions. For further |
| ** information use the contact form at https://www.qt.io/contact-us. |
| ** |
| ** BSD License Usage |
| ** Alternatively, you may use this file under the terms of the BSD license |
| ** as follows: |
| ** |
| ** "Redistribution and use in source and binary forms, with or without |
| ** modification, are permitted provided that the following conditions are |
| ** met: |
| ** * Redistributions of source code must retain the above copyright |
| ** notice, this list of conditions and the following disclaimer. |
| ** * Redistributions in binary form must reproduce the above copyright |
| ** notice, this list of conditions and the following disclaimer in |
| ** the documentation and/or other materials provided with the |
| ** distribution. |
| ** * Neither the name of The Qt Company Ltd nor the names of its |
| ** contributors may be used to endorse or promote products derived |
| ** from this software without specific prior written permission. |
| ** |
| ** |
| ** THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS |
| ** "AS IS" AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT |
| ** LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR |
| ** A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE COPYRIGHT |
| ** OWNER OR CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL, |
| ** SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT |
| ** LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE, |
| ** DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY |
| ** THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT |
| ** (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE |
| ** OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE." |
| ** |
| ** $QT_END_LICENSE$ |
| ** |
| ****************************************************************************/ |
| |
| import Qt3D.Core 2.0 |
| import Qt3D.Render 2.0 |
| import Qt3D.Input 2.0 |
| import Qt3D.Animation 2.9 |
| import Qt3D.Extras 2.0 |
| |
| DefaultSceneEntity { |
| id: scene |
| |
| Entity { |
| id: cube |
| |
| components: [ |
| Transform { |
| id: cubeTransform |
| |
| onTranslationChanged: console.log("t = " + translation) |
| }, |
| CuboidMesh { |
| }, |
| PhongMaterial { |
| id: cubeMaterial |
| ambient: Qt.rgba(0.02, 0.02, 0.02, 1.0) |
| diffuse: "blue" |
| shininess: 50 |
| }, |
| ObjectPicker { |
| onClicked: { |
| if (animator.running == false) { |
| animator.running = true; |
| } else { |
| switch (pick.button) { |
| case PickEvent.RightButton: |
| animationClock.playbackRate *= 2.0; |
| break; |
| case PickEvent.LeftButton: |
| animationClock.playbackRate /= 2.0; |
| break; |
| default: |
| break; |
| } |
| } |
| } |
| }, |
| ClipAnimator { |
| id: animator |
| loops: 3 |
| onRunningChanged: console.log("running = " + running) |
| |
| clock: Clock { |
| id: animationClock |
| playbackRate: 1 |
| } |
| |
| clip: AnimationClipLoader { |
| source: "cubeanimation.json" |
| onDurationChanged: console.log("duration = " + duration) |
| } |
| |
| // By default introspect parent Entity and try |
| // to map fcurve groups to properties of QTransform |
| // mapping: AutomaticAnimationMapping {} |
| |
| // To do more, we can be explicit |
| channelMapper: ChannelMapper { |
| mappings: [ |
| ChannelMapping { channelName: "Location"; target: cubeTransform; property: "translation" }, |
| ChannelMapping { channelName: "Rotation"; target: cubeTransform; property: "rotation" }, |
| ChannelMapping { channelName: "Diffuse Color"; target: cubeMaterial; property: "diffuse" } |
| ] |
| } |
| } |
| ] |
| } |
| |
| camera: Camera { |
| position: Qt.vector3d(10, 3, 15) |
| viewCenter: Qt.vector3d(2.5, 1, 0) |
| } |
| |
| OrbitCameraController { |
| camera: scene.camera |
| linearSpeed: 8 |
| lookSpeed: 180 |
| } |
| } |