| # qmake configuration for the Raspberry Pi 3 (32-bit) using the |
| # *experimental* VC4 driver for Mesa and DRM. |
| # |
| # This should allow accelerated EGL and OpenGL with eglfs via |
| # KMS/DRM/GBM (instead of the Broadcom-specific backend), under X11 |
| # with xcb, and also enables (Qt)Wayland via the standard wayland-egl |
| # path. See https://dri.freedesktop.org/wiki/VC4 |
| # |
| # Note that this is not the same as the default, Broadcom proprietary |
| # driver. Some functionality and extensions may therefore be missing, |
| # in particular when it comes to accelerated multimedia (video, |
| # camera). |
| # |
| # At the time of writing Raspbian has to be switched explicitly to the |
| # experimental VC4 driver. To do this, run raspi-config and enable it |
| # in Advanced Options -> GL Driver. |
| # |
| # Example configure command below. We disable using the GNU gold |
| # linker as it apparently has issues with ARMv8. In the configure |
| # output check that "EGLFS GBM .......... yes" is present, otherwise |
| # eglfs will not be functional. |
| # |
| # ./configure -release -opengl es2 -device linux-rasp-pi3-vc4-g++ \ |
| # -device-option CROSS_COMPILE=~/raspbian/tools/arm-bcm2708/gcc-linaro-arm-linux-gnueabihf-raspbian-x64/bin/arm-linux-gnueabihf- \ |
| # -sysroot ~/raspbian/sysroot \ |
| # -prefix /usr/local/qt5pi -extprefix ~/raspbian/qt5pi -hostprefix ~/raspbian/qt5 \ |
| # -v -nomake examples -nomake tests -no-use-gold-linker |
| |
| include(../common/linux_device_pre.conf) |
| |
| QMAKE_LIBS_EGL += -lEGL |
| QMAKE_LIBS_OPENGL_ES2 += -lGLESv2 -lEGL |
| |
| QMAKE_CFLAGS = -march=armv8-a -mtune=cortex-a53 -mfpu=crypto-neon-fp-armv8 |
| QMAKE_CXXFLAGS = $$QMAKE_CFLAGS |
| |
| DISTRO_OPTS += hard-float |
| DISTRO_OPTS += deb-multi-arch |
| |
| EGLFS_DEVICE_INTEGRATION = eglfs_kms |
| |
| include(../common/linux_arm_device_post.conf) |
| |
| load(qt_config) |