| /**************************************************************************** |
| ** |
| ** Copyright (C) 2017 The Qt Company Ltd. |
| ** Contact: http://www.qt.io/licensing/ |
| ** |
| ** This file is part of the Qt Quick Controls 2 module of the Qt Toolkit. |
| ** |
| ** $QT_BEGIN_LICENSE:LGPL3$ |
| ** Commercial License Usage |
| ** Licensees holding valid commercial Qt licenses may use this file in |
| ** accordance with the commercial license agreement provided with the |
| ** Software or, alternatively, in accordance with the terms contained in |
| ** a written agreement between you and The Qt Company. For licensing terms |
| ** and conditions see http://www.qt.io/terms-conditions. For further |
| ** information use the contact form at http://www.qt.io/contact-us. |
| ** |
| ** GNU Lesser General Public License Usage |
| ** Alternatively, this file may be used under the terms of the GNU Lesser |
| ** General Public License version 3 as published by the Free Software |
| ** Foundation and appearing in the file LICENSE.LGPLv3 included in the |
| ** packaging of this file. Please review the following information to |
| ** ensure the GNU Lesser General Public License version 3 requirements |
| ** will be met: https://www.gnu.org/licenses/lgpl.html. |
| ** |
| ** GNU General Public License Usage |
| ** Alternatively, this file may be used under the terms of the GNU |
| ** General Public License version 2.0 or later as published by the Free |
| ** Software Foundation and appearing in the file LICENSE.GPL included in |
| ** the packaging of this file. Please review the following information to |
| ** ensure the GNU General Public License version 2.0 requirements will be |
| ** met: http://www.gnu.org/licenses/gpl-2.0.html. |
| ** |
| ** $QT_END_LICENSE$ |
| ** |
| ****************************************************************************/ |
| |
| import QtQuick 2.12 |
| import QtQuick.Controls 2.12 |
| import QtQuick.Templates 2.12 as T |
| import QtQuick.Controls.Material 2.12 |
| import QtQuick.Controls.Material.impl 2.12 |
| import QtQuick.Window 2.12 |
| |
| T.Menu { |
| id: control |
| |
| Material.elevation: 8 |
| |
| implicitWidth: Math.max(implicitBackgroundWidth + leftInset + rightInset, |
| contentWidth + leftPadding + rightPadding) |
| implicitHeight: Math.max(implicitBackgroundHeight + topInset + bottomInset, |
| contentHeight + topPadding + bottomPadding) |
| |
| margins: 0 |
| verticalPadding: 8 |
| |
| transformOrigin: !cascade ? Item.Top : (mirrored ? Item.TopRight : Item.TopLeft) |
| |
| delegate: MenuItem { } |
| |
| enter: Transition { |
| // grow_fade_in |
| NumberAnimation { property: "scale"; from: 0.9; to: 1.0; easing.type: Easing.OutQuint; duration: 220 } |
| NumberAnimation { property: "opacity"; from: 0.0; to: 1.0; easing.type: Easing.OutCubic; duration: 150 } |
| } |
| |
| exit: Transition { |
| // shrink_fade_out |
| NumberAnimation { property: "scale"; from: 1.0; to: 0.9; easing.type: Easing.OutQuint; duration: 220 } |
| NumberAnimation { property: "opacity"; from: 1.0; to: 0.0; easing.type: Easing.OutCubic; duration: 150 } |
| } |
| |
| contentItem: ListView { |
| implicitHeight: contentHeight |
| |
| model: control.contentModel |
| interactive: Window.window ? contentHeight > Window.window.height : false |
| clip: true |
| currentIndex: control.currentIndex |
| |
| ScrollIndicator.vertical: ScrollIndicator {} |
| } |
| |
| background: Rectangle { |
| implicitWidth: 200 |
| implicitHeight: control.Material.menuItemHeight |
| |
| radius: 3 |
| color: control.Material.dialogColor |
| |
| layer.enabled: control.Material.elevation > 0 |
| layer.effect: ElevationEffect { |
| elevation: control.Material.elevation |
| } |
| } |
| |
| T.Overlay.modal: Rectangle { |
| color: control.Material.backgroundDimColor |
| Behavior on opacity { NumberAnimation { duration: 150 } } |
| } |
| |
| T.Overlay.modeless: Rectangle { |
| color: control.Material.backgroundDimColor |
| Behavior on opacity { NumberAnimation { duration: 150 } } |
| } |
| } |