qt-everywhere-src-5.14.1/qtwayland/examples/wayland/spanning-screens/main.qml

/****************************************************************************
**
** Copyright (C) 2018 The Qt Company Ltd.
** Contact: http://www.qt-project.org/legal
**
** This file is part of the examples of the Qt Toolkit.
**
** $QT_BEGIN_LICENSE:BSD$
** Commercial License Usage
** Licensees holding valid commercial Qt licenses may use this file in
** accordance with the commercial license agreement provided with the
** Software or, alternatively, in accordance with the terms contained in
** a written agreement between you and The Qt Company. For licensing terms
** and conditions see https://www.qt.io/terms-conditions. For further
** information use the contact form at https://www.qt.io/contact-us.
**
** BSD License Usage
** Alternatively, you may use this file under the terms of the BSD license
** as follows:
**
** "Redistribution and use in source and binary forms, with or without
** modification, are permitted provided that the following conditions are
** met:
**   * Redistributions of source code must retain the above copyright
**     notice, this list of conditions and the following disclaimer.
**   * Redistributions in binary form must reproduce the above copyright
**     notice, this list of conditions and the following disclaimer in
**     the documentation and/or other materials provided with the
**     distribution.
**   * Neither the name of The Qt Company Ltd nor the names of its
**     contributors may be used to endorse or promote products derived
**     from this software without specific prior written permission.
**
**
** THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS
** "AS IS" AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT
** LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR
** A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE COPYRIGHT
** OWNER OR CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL,
** SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT
** LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE,
** DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY
** THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT
** (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE
** OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE."
**
** $QT_END_LICENSE$
**
****************************************************************************/

import QtQuick 2.6
import QtQuick.Window 2.3
import QtWayland.Compositor 1.3

WaylandCompositor {
    WaylandOutput {
        sizeFollowsWindow: true
        window: Window {
            id: topSurfaceArea

            property int pixelHeight: screen.devicePixelRatio * height
            property int pixelWidth: screen.devicePixelRatio * width

            width: 1024
            height: 768
            visible: true
            color: "#1337af"

            Text { text: "Top screen" }

            // Enable the following to make the output target an actual screen,
            // for example when running on eglfs in a multi-display embedded system.

            // screen: Qt.application.screens[0]
        }
    }

    WaylandOutput {
        sizeFollowsWindow: true
        window: Window {
            id: bottomSurfaceArea

            property int pixelHeight: screen.devicePixelRatio * height
            property int pixelWidth: screen.devicePixelRatio * width

            width: 1024
            height: 768
            visible: true
            color: "#1abacc"

            Text { text: "Bottom screen" }

            // Enable the following to make the output target an actual screen,
            // for example when running on eglfs in a multi-display embedded system.

            // screen: Qt.application.screens[1]
        }
    }

    Component {
        id: chromeComponent
        ShellSurfaceItem {
            autoCreatePopupItems: true
            onSurfaceDestroyed: destroy()
        }
    }

    XdgShell {
        onToplevelCreated: {
            const shellSurface = xdgSurface;

            const topItem = chromeComponent.createObject(topSurfaceArea, {
                shellSurface
            });

            const bottomItem = chromeComponent.createObject(bottomSurfaceArea, {
                shellSurface,
                y: Qt.binding(function() { return -topSurfaceArea.height;})
            });

            const height = topSurfaceArea.pixelHeight + bottomSurfaceArea.pixelHeight;
            const width = Math.max(bottomSurfaceArea.pixelWidth, topSurfaceArea.pixelWidth);
            const size = Qt.size(width, height);
            toplevel.sendFullscreen(size);
        }
    }
}