| /**************************************************************************** |
| ** |
| ** Copyright (C) 2017 The Qt Company Ltd. |
| ** Contact: https://www.qt.io/licensing/ |
| ** |
| ** This file is part of the examples of the Qt Toolkit. |
| ** |
| ** $QT_BEGIN_LICENSE:BSD$ |
| ** Commercial License Usage |
| ** Licensees holding valid commercial Qt licenses may use this file in |
| ** accordance with the commercial license agreement provided with the |
| ** Software or, alternatively, in accordance with the terms contained in |
| ** a written agreement between you and The Qt Company. For licensing terms |
| ** and conditions see https://www.qt.io/terms-conditions. For further |
| ** information use the contact form at https://www.qt.io/contact-us. |
| ** |
| ** BSD License Usage |
| ** Alternatively, you may use this file under the terms of the BSD license |
| ** as follows: |
| ** |
| ** "Redistribution and use in source and binary forms, with or without |
| ** modification, are permitted provided that the following conditions are |
| ** met: |
| ** * Redistributions of source code must retain the above copyright |
| ** notice, this list of conditions and the following disclaimer. |
| ** * Redistributions in binary form must reproduce the above copyright |
| ** notice, this list of conditions and the following disclaimer in |
| ** the documentation and/or other materials provided with the |
| ** distribution. |
| ** * Neither the name of The Qt Company Ltd nor the names of its |
| ** contributors may be used to endorse or promote products derived |
| ** from this software without specific prior written permission. |
| ** |
| ** |
| ** THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS |
| ** "AS IS" AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT |
| ** LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR |
| ** A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE COPYRIGHT |
| ** OWNER OR CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL, |
| ** SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT |
| ** LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE, |
| ** DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY |
| ** THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT |
| ** (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE |
| ** OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE." |
| ** |
| ** $QT_END_LICENSE$ |
| ** |
| ****************************************************************************/ |
| |
| import QtQuick 2.12 |
| import QtQuick.Window 2.1 |
| |
| Item { |
| id: tabWidget |
| |
| // Setting the default property to stack.children means any child items |
| // of the TabWidget are actually added to the 'stack' item's children. |
| // See the "Property Binding" |
| // documentation for details on default properties. |
| default property alias content: stack.children |
| |
| property int current: 0 |
| |
| onCurrentChanged: setZOrders() |
| Component.onCompleted: setZOrders() |
| |
| function setZOrders() { |
| for (var i = 0; i < stack.children.length; ++i) { |
| stack.children[i].z = (i == current ? 1 : 0) |
| stack.children[i].enabled = (i == current) |
| } |
| } |
| |
| Row { |
| id: header |
| |
| Repeater { |
| model: stack.children.length |
| delegate: Rectangle { |
| required property int index |
| width: tabWidget.width / stack.children.length |
| height: Math.max(Screen.pixelDensity * 7, label.implicitHeight * 1.2) |
| |
| Rectangle { |
| width: parent.width; height: 1 |
| anchors { bottom: parent.bottom; bottomMargin: 1 } |
| color: "#acb2c2" |
| } |
| BorderImage { |
| anchors { fill: parent; leftMargin: 2; topMargin: 5; rightMargin: 1 } |
| border { left: 7; right: 7 } |
| source: "images/tab.png" |
| visible: tabWidget.current == parent.index |
| } |
| Text { |
| id: label |
| horizontalAlignment: Qt.AlignHCenter; verticalAlignment: Qt.AlignVCenter |
| anchors.fill: parent |
| text: stack.children[parent.index].title |
| elide: Text.ElideRight |
| font.bold: tabWidget.current == parent.index |
| } |
| TapHandler { |
| onTapped: tabWidget.current = parent.index |
| } |
| } |
| } |
| } |
| |
| Item { |
| id: stack |
| width: tabWidget.width |
| anchors.top: header.bottom; anchors.bottom: tabWidget.bottom |
| } |
| } |