| /**************************************************************************** |
| ** |
| ** Copyright (C) 2017 The Qt Company Ltd. |
| ** Contact: http://www.qt.io/licensing/ |
| ** |
| ** This file is part of the Qt Quick Controls 2 module of the Qt Toolkit. |
| ** |
| ** $QT_BEGIN_LICENSE:LGPL3$ |
| ** Commercial License Usage |
| ** Licensees holding valid commercial Qt licenses may use this file in |
| ** accordance with the commercial license agreement provided with the |
| ** Software or, alternatively, in accordance with the terms contained in |
| ** a written agreement between you and The Qt Company. For licensing terms |
| ** and conditions see http://www.qt.io/terms-conditions. For further |
| ** information use the contact form at http://www.qt.io/contact-us. |
| ** |
| ** GNU Lesser General Public License Usage |
| ** Alternatively, this file may be used under the terms of the GNU Lesser |
| ** General Public License version 3 as published by the Free Software |
| ** Foundation and appearing in the file LICENSE.LGPLv3 included in the |
| ** packaging of this file. Please review the following information to |
| ** ensure the GNU Lesser General Public License version 3 requirements |
| ** will be met: https://www.gnu.org/licenses/lgpl.html. |
| ** |
| ** GNU General Public License Usage |
| ** Alternatively, this file may be used under the terms of the GNU |
| ** General Public License version 2.0 or later as published by the Free |
| ** Software Foundation and appearing in the file LICENSE.GPL included in |
| ** the packaging of this file. Please review the following information to |
| ** ensure the GNU General Public License version 2.0 requirements will be |
| ** met: http://www.gnu.org/licenses/gpl-2.0.html. |
| ** |
| ** $QT_END_LICENSE$ |
| ** |
| ****************************************************************************/ |
| |
| import QtQuick 2.15 |
| import QtQuick.Window 2.15 |
| import QtQuick.Controls 2.15 |
| import QtQuick.Controls.impl 2.15 |
| import QtQuick.Templates 2.15 as T |
| |
| T.ComboBox { |
| id: control |
| |
| implicitWidth: Math.max(implicitBackgroundWidth + leftInset + rightInset, |
| implicitContentWidth + leftPadding + rightPadding) |
| implicitHeight: Math.max(implicitBackgroundHeight + topInset + bottomInset, |
| implicitContentHeight + topPadding + bottomPadding, |
| implicitIndicatorHeight + topPadding + bottomPadding) |
| |
| leftPadding: padding + (!control.mirrored || !indicator || !indicator.visible ? 0 : indicator.width + spacing) |
| rightPadding: padding + (control.mirrored || !indicator || !indicator.visible ? 0 : indicator.width + spacing) |
| |
| delegate: ItemDelegate { |
| width: ListView.view.width |
| text: control.textRole ? (Array.isArray(control.model) ? modelData[control.textRole] : model[control.textRole]) : modelData |
| palette.text: control.palette.text |
| palette.highlightedText: control.palette.highlightedText |
| font.weight: control.currentIndex === index ? Font.DemiBold : Font.Normal |
| highlighted: control.highlightedIndex === index |
| hoverEnabled: control.hoverEnabled |
| } |
| |
| indicator: ColorImage { |
| x: control.mirrored ? control.padding : control.width - width - control.padding |
| y: control.topPadding + (control.availableHeight - height) / 2 |
| color: control.palette.dark |
| defaultColor: "#353637" |
| source: "qrc:/qt-project.org/imports/QtQuick/Controls.2/images/double-arrow.png" |
| opacity: enabled ? 1 : 0.3 |
| } |
| |
| contentItem: T.TextField { |
| leftPadding: !control.mirrored ? 12 : control.editable && activeFocus ? 3 : 1 |
| rightPadding: control.mirrored ? 12 : control.editable && activeFocus ? 3 : 1 |
| topPadding: 6 - control.padding |
| bottomPadding: 6 - control.padding |
| |
| text: control.editable ? control.editText : control.displayText |
| |
| enabled: control.editable |
| autoScroll: control.editable |
| readOnly: control.down |
| inputMethodHints: control.inputMethodHints |
| validator: control.validator |
| selectByMouse: control.selectTextByMouse |
| |
| font: control.font |
| color: control.editable ? control.palette.text : control.palette.buttonText |
| selectionColor: control.palette.highlight |
| selectedTextColor: control.palette.highlightedText |
| verticalAlignment: Text.AlignVCenter |
| |
| background: Rectangle { |
| visible: control.enabled && control.editable && !control.flat |
| border.width: parent && parent.activeFocus ? 2 : 1 |
| border.color: parent && parent.activeFocus ? control.palette.highlight : control.palette.button |
| color: control.palette.base |
| } |
| } |
| |
| background: Rectangle { |
| implicitWidth: 140 |
| implicitHeight: 40 |
| |
| color: control.down ? control.palette.mid : control.palette.button |
| border.color: control.palette.highlight |
| border.width: !control.editable && control.visualFocus ? 2 : 0 |
| visible: !control.flat || control.down |
| } |
| |
| popup: T.Popup { |
| y: control.height |
| width: control.width |
| height: Math.min(contentItem.implicitHeight, control.Window.height - topMargin - bottomMargin) |
| topMargin: 6 |
| bottomMargin: 6 |
| |
| contentItem: ListView { |
| clip: true |
| implicitHeight: contentHeight |
| model: control.delegateModel |
| currentIndex: control.highlightedIndex |
| highlightMoveDuration: 0 |
| |
| Rectangle { |
| z: 10 |
| width: parent.width |
| height: parent.height |
| color: "transparent" |
| border.color: control.palette.mid |
| } |
| |
| T.ScrollIndicator.vertical: ScrollIndicator { } |
| } |
| |
| background: Rectangle { |
| color: control.palette.window |
| } |
| } |
| } |