| # |
| # qmake configuration for the Freescale iMX6 boards (single, dual and quad) |
| # |
| # The configuration below is set up for running with EGL on the framebuffer via |
| # the eglfs platform plugin and its eglfs_viv backend. |
| |
| # Wayland is also fully functional out of the box. However, when writing Wayland |
| # *compositors* with Qt, the eglfs backend will have to be switched to |
| # eglfs_viv_wl by setting the QT_QPA_EGLFS_INTEGRATION environment variable. |
| # |
| # Below is an example configure line that assumes the SDK is in |
| # $HOME/imx6/toolchain. On device Qt is expected to be placed under |
| # /usr/local/qt5 whereas on the host 'make install' will copy the host tools and |
| # the target libraries to $HOME/imx6/qt5. |
| # |
| # ./configure -prefix /usr/local/qt5 -extprefix $HOME/imx6/qt5 -device linux-imx6-g++ \ |
| # -device-option CROSS_COMPILE=$HOME/imx6/toolchain/sysroots/x86_64-pokysdk-linux/usr/bin/arm-poky-linux-gnueabi/arm-poky-linux-gnueabi- \ |
| # -sysroot $HOME/imx6/toolchain/sysroots/cortexa9hf-vfp-neon-poky-linux-gnueabi \ |
| # -nomake examples -nomake tests -v |
| # |
| |
| include(../common/linux_device_pre.conf) |
| |
| QMAKE_LIBS_EGL += -lEGL |
| QMAKE_LIBS_OPENGL_ES2 += -lGLESv2 -lEGL -lGAL |
| QMAKE_LIBS_OPENVG += -lOpenVG -lEGL -lGAL |
| |
| IMX6_CFLAGS = -march=armv7-a -mfpu=neon -DLINUX=1 -DEGL_API_FB=1 |
| QMAKE_CFLAGS += $$IMX6_CFLAGS |
| QMAKE_CXXFLAGS += $$IMX6_CFLAGS |
| |
| DISTRO_OPTS += hard-float |
| |
| # Preferred eglfs backend |
| EGLFS_DEVICE_INTEGRATION = eglfs_viv |
| |
| include(../common/linux_arm_device_post.conf) |
| |
| load(qt_config) |
