| /**************************************************************************** |
| ** |
| ** Copyright (C) 2016 The Qt Company Ltd. |
| ** Contact: https://www.qt.io/licensing/ |
| ** |
| ** This file is part of the QtScxml module of the Qt Toolkit. |
| ** |
| ** $QT_BEGIN_LICENSE:BSD$ |
| ** Commercial License Usage |
| ** Licensees holding valid commercial Qt licenses may use this file in |
| ** accordance with the commercial license agreement provided with the |
| ** Software or, alternatively, in accordance with the terms contained in |
| ** a written agreement between you and The Qt Company. For licensing terms |
| ** and conditions see https://www.qt.io/terms-conditions. For further |
| ** information use the contact form at https://www.qt.io/contact-us. |
| ** |
| ** BSD License Usage |
| ** Alternatively, you may use this file under the terms of the BSD license |
| ** as follows: |
| ** |
| ** "Redistribution and use in source and binary forms, with or without |
| ** modification, are permitted provided that the following conditions are |
| ** met: |
| ** * Redistributions of source code must retain the above copyright |
| ** notice, this list of conditions and the following disclaimer. |
| ** * Redistributions in binary form must reproduce the above copyright |
| ** notice, this list of conditions and the following disclaimer in |
| ** the documentation and/or other materials provided with the |
| ** distribution. |
| ** * Neither the name of The Qt Company Ltd nor the names of its |
| ** contributors may be used to endorse or promote products derived |
| ** from this software without specific prior written permission. |
| ** |
| ** |
| ** THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS |
| ** "AS IS" AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT |
| ** LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR |
| ** A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE COPYRIGHT |
| ** OWNER OR CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL, |
| ** SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT |
| ** LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE, |
| ** DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY |
| ** THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT |
| ** (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE |
| ** OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE." |
| ** |
| ** $QT_END_LICENSE$ |
| ** |
| ****************************************************************************/ |
| |
| import CalculatorStateMachine 1.0 |
| import QtQuick 2.5 |
| import QtQuick.Window 2.2 |
| import QtScxml 5.8 |
| |
| Window { |
| id: window |
| visible: true |
| width: 320 |
| height: 480 |
| |
| CalculatorStateMachine { |
| id: statemachine |
| running: true |
| EventConnection { |
| events: ["updateDisplay"] |
| onOccurred: resultText.text = event.data.display |
| } |
| } |
| |
| Rectangle { |
| id: resultArea |
| anchors.left: parent.left |
| anchors.right: parent.right |
| anchors.top: parent.top |
| height: parent.height * 3 / 8 - 10 |
| border.color: "white" |
| border.width: 1 |
| color: "#46a2da" |
| Text { |
| id: resultText |
| anchors.leftMargin: buttons.implicitMargin |
| anchors.rightMargin: buttons.implicitMargin |
| anchors.fill: parent |
| horizontalAlignment: Text.AlignRight |
| verticalAlignment: Text.AlignVCenter |
| text: "0" |
| color: "white" |
| font.pixelSize: window.height * 3 / 32 |
| font.family: "Open Sans Regular" |
| fontSizeMode: Text.Fit |
| } |
| } |
| |
| Item { |
| id: buttons |
| anchors.top: resultArea.bottom |
| anchors.left: parent.left |
| anchors.right: parent.right |
| anchors.bottom: parent.bottom |
| property real implicitMargin: { |
| var ret = 0; |
| for (var i = 0; i < visibleChildren.length; ++i) { |
| var child = visibleChildren[i]; |
| ret += (child.implicitMargin || 0); |
| } |
| return ret / visibleChildren.length; |
| } |
| |
| Repeater { |
| id: operations |
| model: ["÷", "×", "+", "-"] |
| Button { |
| y: 0 |
| x: index * width |
| width: parent.width / 4 |
| height: parent.height / 5 |
| color: pressed ? "#5caa15" : "#80c342" |
| text: modelData |
| fontHeight: 0.4 |
| onClicked: statemachine.submitEvent(eventName) |
| property string eventName: { |
| switch (text) { |
| case "÷": return "OPER.DIV" |
| case "×": return "OPER.STAR" |
| case "+": return "OPER.PLUS" |
| case "-": return "OPER.MINUS" |
| } |
| } |
| } |
| } |
| |
| Repeater { |
| id: digits |
| model: ["7", "8", "9", "4", "5", "6", "1", "2", "3", "0", ".", "C"] |
| Button { |
| x: (index % 3) * width |
| y: Math.floor(index / 3 + 1) * height |
| width: parent.width / 4 |
| height: parent.height / 5 |
| color: pressed ? "#d6d6d6" : "#eeeeee" |
| text: modelData |
| onClicked: statemachine.submitEvent(eventName) |
| property string eventName: { |
| switch (text) { |
| case ".": return "POINT" |
| case "C": return "C" |
| default: return "DIGIT." + text |
| } |
| } |
| } |
| } |
| |
| Button { |
| id: resultButton |
| x: 3 * width |
| y: parent.height / 5 |
| textHeight: y - 2 |
| fontHeight: 0.4 |
| width: parent.width / 4 |
| height: y * 4 |
| color: pressed ? "#e0b91c" : "#face20" |
| text: "=" |
| onClicked: statemachine.submitEvent("EQUALS") |
| } |
| } |
| } |