v5.18.0/website/docs/r/bigtable_table_iam.html.markdown

---
subcategory: "Cloud Bigtable"
description: |-
 Collection of resources to manage IAM policy for a Bigtable Table.
---

# IAM policy for Bigtable table

Three different resources help you manage IAM policies on bigtable tables. Each of these resources serves a different use case:

* `google_bigtable_table_iam_policy`: Authoritative. Sets the IAM policy for the tables and replaces any existing policy already attached.
* `google_bigtable_table_iam_binding`: Authoritative for a given role. Updates the IAM policy to grant a role to a list of members. Other roles within the IAM policy for the table are preserved.
* `google_bigtable_table_iam_member`: Non-authoritative. Updates the IAM policy to grant a role to a new member. Other members for the role for the table are preserved.

~> **Note:** `google_bigtable_table_iam_policy` **cannot** be used in conjunction with `google_bigtable_table_iam_binding` and `google_bigtable_table_iam_member` or they will fight over what your policy should be. In addition, be careful not to accidentally unset ownership of the table as `google_bigtable_table_iam_policy` replaces the entire policy.

~> **Note:** `google_bigtable_table_iam_binding` resources **can be** used in conjunction with `google_bigtable_table_iam_member` resources **only if** they do not grant privilege to the same role.

## google\_bigtable\_table\_iam\_policy

```hcl
data "google_iam_policy" "admin" {
  binding {
    role = "roles/bigtable.user"
    members = [
      "user:jane@example.com",
    ]
  }
}

resource "google_bigtable_table_iam_policy" "editor" {
  project     = "your-project"
  instance    = "your-bigtable-instance"
  table       = "your-bigtable-table"
  policy_data = data.google_iam_policy.admin.policy_data
}
```

## google\_bigtable\_table\_iam\_binding

```hcl
resource "google_bigtable_table_iam_binding" "editor" {
  table       = "your-bigtable-table"
  instance    = "your-bigtable-instance"
  role     = "roles/bigtable.user"
  members = [
    "user:jane@example.com",
  ]
}
```

## google\_bigtable\_table\_iam\_member

```hcl
resource "google_bigtable_table_iam_member" "editor" {
  table       = "your-bigtable-table"
  instance    = "your-bigtable-instance"
  role        = "roles/bigtable.user"
  member      = "user:jane@example.com"
}
```

## Argument Reference

The following arguments are supported:

* `instance` - (Required) The name or relative resource id of the instance that owns the table.

* `table` - (Required) The name or relative resource id of the table to manage IAM policies for.

For `google_bigtable_table_iam_member` or `google_bigtable_table_iam_binding`:

* `member/members` - (Required) Identities that will be granted the privilege in `role`.
  Each entry can have one of the following values:
  * **allUsers**: A special identifier that represents anyone who is on the internet; with or without a Google account.
  * **allAuthenticatedUsers**: A special identifier that represents anyone who is authenticated with a Google account or a service account.
  * **user:{emailid}**: An email address that represents a specific Google account. For example, alice@gmail.com or joe@example.com.
  * **serviceAccount:{emailid}**: An email address that represents a service account. For example, my-other-app@appspot.gserviceaccount.com.
  * **group:{emailid}**: An email address that represents a Google group. For example, admins@example.com.
  * **domain:{domain}**: A G Suite domain (primary, instead of alias) name that represents all the users of that domain. For example, google.com or example.com.

* `role` - (Required) The role that should be applied. Only one
    `google_bigtable_table_iam_binding` can be used per role. Note that custom roles must be of the format
    `[projects|organizations]/{parent-name}/roles/{role-name}`. Read more about roles [here](https://cloud.google.com/bigtable/docs/access-control#roles).

`google_bigtable_table_iam_policy` only:
* `policy_data` - (Required) The policy data generated by a `google_iam_policy` data source.

- - -

* `project` - (Optional) The project in which the table belongs. If it
    is not provided, Terraform will use the provider default.

## Attributes Reference

In addition to the arguments listed above, the following computed attributes are
exported:

* `etag` - (Computed) The etag of the tables's IAM policy.

## Import


-> **Custom Roles**: If you're importing a IAM resource with a custom role, make sure to use the
 full name of the custom role, e.g. `[projects/my-project|organizations/my-org]/roles/my-custom-role`.

### Importing IAM members

IAM member imports use space-delimited identifiers that contain the resource's `table`, `role`, and `member`. For example:

* `"projects/{project}/instances/{instance}/tables/{table} roles/editor user:jane@example.com"`

An [`import` block](https://developer.hashicorp.com/terraform/language/import) (Terraform v1.5.0 and later) can be used to import IAM members:

```tf
import {
  id = "projects/{project}/instances/{instance}/tables/{table} roles/editor user:jane@example.com"
  to = google_bigtable_table_iam_member.default
}
```

The [`terraform import` command](https://developer.hashicorp.com/terraform/cli/commands/import) can also be used:

```
$ terraform import google_bigtable_table_iam_member.default "projects/{project}/instances/{instance}/tables/{table} roles/editor user:jane@example.com"
```

### Importing IAM bindings

IAM binding imports use space-delimited identifiers that contain the resource's `table` and `role`. For example:

* `"projects/{project}/instances/{instance}/tables/{table} roles/editor"`

An [`import` block](https://developer.hashicorp.com/terraform/language/import) (Terraform v1.5.0 and later) can be used to import IAM bindings:

```tf
import {
  id = "projects/{project}/instances/{instance}/tables/{table} roles/editor"
  to = google_bigtable_table_iam_binding.default
}
```

The [`terraform import` command](https://developer.hashicorp.com/terraform/cli/commands/import) can also be used:

```
$ terraform import google_bigtable_table_iam_binding.default "projects/{project}/instances/{instance}/tables/{table} roles/editor"
```

### Importing IAM policies

IAM policy imports use the `table` identifier of the Bigtable Table resource only. For example:

* `"projects/{project}/instances/{instance}/tables/{table}"`

An [`import` block](https://developer.hashicorp.com/terraform/language/import) (Terraform v1.5.0 and later) can be used to import IAM policies:

```tf
import {
  id = "projects/{project}/instances/{instance}/tables/{table}"
  to = google_bigtable_table_iam_policy.default
}
```

The [`terraform import` command](https://developer.hashicorp.com/terraform/cli/commands/import) can also be used:

```
$ terraform import google_bigtable_table_iam_policy.default projects/{project}/instances/{instance}/tables/{table}
```